-
Notifications
You must be signed in to change notification settings - Fork 2
/
build.gradle.kts
90 lines (73 loc) · 2.3 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
plugins {
id("application")
id("org.openjfx.javafxplugin") version "0.1.0"
id("antlr")
id("org.panteleyev.jpackageplugin") version "1.6.0"
}
repositories {
mavenCentral()
}
dependencies {
implementation("org.antlr:antlr4-runtime:4.13.1")
implementation("org.jspecify:jspecify:0.3.0")
implementation("org.apache.commons:commons-csv:1.11.0")
implementation("org.eclipse.store:storage-embedded:1.3.2")
implementation("org.eclipse.store:storage-embedded-configuration:1.3.2")
implementation("org.slf4j:slf4j-nop:2.0.13")
testImplementation("org.junit.jupiter:junit-jupiter-api:5.10.0")
testImplementation("org.junit.jupiter:junit-jupiter-engine:5.10.0")
antlr("org.antlr:antlr4:4.13.1")
}
application {
mainModule = "link.biosmarcel.baka"
mainClass = "link.biosmarcel.baka.Main"
}
tasks.generateGrammarSource {
maxHeapSize = "64m"
arguments = arguments +
listOf(
"-visitor", "-long-messages",
"-package", "link.biosmarcel.baka"
)
outputDirectory = File("${layout.buildDirectory.get()}/generated-src/antlr/main/link/biosmarcel/baka")
}
javafx {
version = "22.0.2"
modules = listOf("javafx.controls")
}
tasks.withType<JavaCompile> {
options.encoding = "UTF-8"
}
tasks.withType<Test> {
systemProperty("file.encoding", "UTF-8")
}
java {
toolchain {
languageVersion = JavaLanguageVersion.of(22)
}
}
task("copyDependencies", Copy::class) {
from(configurations.runtimeClasspath).into("${layout.buildDirectory.get()}/jmods")
}
task("copyJar", Copy::class) {
from(tasks.jar).into("${layout.buildDirectory.get()}/jmods")
}
tasks.jpackage {
dependsOn("build", "copyDependencies", "copyJar")
appVersion = project.version.toString()
appName = "Baka"
vendor = "biosmarcel"
// FIXME Generate runtime
runtimeImage = System.getProperty("java.home")
module = "link.biosmarcel.baka/link.biosmarcel.baka.Main"
modulePaths = listOf("${layout.buildDirectory.get()}/jmods")
destination = "${layout.buildDirectory.get()}/dist"
javaOptions = listOf("-Dfile.encoding=UTF-8")
windows {
winMenu = true
winPerUserInstall = true
icon = "icon.ico"
winUpgradeUuid = "992b362a-998c-4a30-ab65-7c380540aefa"
}
}
version = "1.0.0"