settings.gradle

import groovy.json.JsonSlurper

pluginManagement {
    repositories {
        mavenLocal()

        maven {
            name("NyanMaven Mirror")
            url("https://maven.hendrixshen.top/mirror")
        }

        maven {
            name("Jitpack")
            url("https://jitpack.io")
        }

        mavenCentral()
        gradlePluginPortal()
    }

    resolutionStrategy {
        eachPlugin {
            switch (requested.id.id) {
                case "com.replaymod.preprocess": {
                    useModule("com.github.Fallen-Breath:preprocessor:${requested.version}")
                    break
                }
            }
        }
    }
}

ext {
    File localPropsFile = file("${rootDir}/local.properties")

    if (localPropsFile.exists()) {
        Properties p = new Properties()
        p.load(new FileInputStream(localPropsFile))
        p.each { key, value ->
            ext[key as String] = value
        }
    }

    getOrDefault = { String key, String defaultValue ->
        if (!ext.has(key)) {
            return defaultValue
        }

        String value = ext.getProperty(key)
        return value.isEmpty() ? defaultValue : value
    }
}

def versions = Arrays.asList(
        "1.14.4",
        "1.15.2",
        "1.16.5",
        "1.17.1",
        "1.18.2",
        "1.19.2",
        "1.19.3",
        "1.19.4",
        "1.20.1",
        "1.20.2",
        "1.20.4",
)

Map<String, List<String>> settings = file("settings.json").withReader {
    new JsonSlurper().parse(it) as Map<String, List<String>>
}

for (String version : settings.get("versions")) {
    include(":$version")
    ProjectDescriptor proj = project(":$version")
    proj.setProjectDir(file("versions/$version"))
    proj.setBuildFileName("../${settings.versions.get(0)}/build.gradle")
}