publish-maven.gradle

apply plugin: "propdeps-maven"

install {
	repositories.mavenInstaller {
		customizePom(pom, project)
	}
}

def customizePom(pom, gradleProject) {
	pom.whenConfigured { generatedPom ->
		// eliminate test-scoped dependencies (no need in maven central poms)
		generatedPom.dependencies.removeAll { dep ->
			dep.scope == "test"
		}

		// sort to make pom dependencies order consistent to ease comparison of older poms
		generatedPom.dependencies = generatedPom.dependencies.sort { dep ->
			"$dep.scope:$dep.groupId:$dep.artifactId"
		}

		// add all items necessary for maven central publication
		generatedPom.project {
			name = gradleProject.description
			description = gradleProject.description
			url = "https://github.com/SpringSource/spring-webflow"
			organization {
				name = "SpringSource"
				url = "http://springsource.org/spring-webflow"
			}
			licenses {
				license {
					name "The Apache Software License, Version 2.0"
					url "http://www.apache.org/licenses/LICENSE-2.0.txt"
					distribution "repo"
				}
			}
			scm {
				url = "https://github.com/SpringSource/spring-webflow"
				connection = "scm:git:git://github.com/SpringSource/spring-webflow"
				developerConnection = "scm:git:git://github.com/SpringSource/spring-webflow"
			}
			developers {
				developer {
					id = "rstoyanchev"
					name = "Rossen Stoyanchev"
					email = "rstoyanchev@vmware.com"
				}
				developer {
					id = "pwebb"
					name = "Phil Webb"
					email = "pwebb@vmware.com"
				}
			}
		}
	}
}