forked from lorents17/iCatalyst
-
Notifications
You must be signed in to change notification settings - Fork 1
/
iCatalyst.bat
1307 lines (1242 loc) · 38 KB
/
iCatalyst.bat
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
@echo off
::Lorents & Res2001 2010-2016
setlocal enabledelayedexpansion
if #thrd# equ #%~1# call:threadwork %4 %5 "%~2" "%~3" & exit /b
if #updateic# equ #%~1# call:icupdate & exit /b
set "name=Image Catalyst"
set "version=2.7"
set "oldtitle="
set "consolepid="
call:getpid consolepid
call:gettitle oldtitle
title %name%
set "spacebar=-------------------------------------------------------------------------------"
if ## equ #%~1# call:helpmsg & exit /b
set "fullname=%~0"
set "scrpath=%~dp0"
set "sconfig=%scrpath%Tools\"
set "scripts=%scrpath%Tools\scripts\"
set "tmppath=%TEMP%\iCatalyst\"
set "errortimewait=3000"
set "iclock=%TEMP%ic.lck"
set "LOG=%scrpath%\iCatalyst"
if exist "%systemroot%\system32\timeout.exe" (set "istimeout=yes") else set "istimeout="
::call:runningcheck "%name% %version%"
::echo.This process is work&pause & title %oldtitle%&exit /b
set "LOG=%LOG%%runic%"
set "apps=%~dp0Tools\apps\"
PATH %apps%;%PATH%
set "nofile="
set "num=0"
for %%a in (
"%sconfig%config.ini"
"%apps%advdef.exe"
"%apps%deflopt.exe"
"%apps%browsefolder.exe"
"%apps%gifsicle.exe"
"%apps%jpegstripper.exe"
"%apps%jpginfo.exe"
"%apps%jpegtran.exe"
"%apps%pngwolfzopfli.exe"
"%apps%truepng.exe"
"%scripts%pfilter.js"
"%scripts%filter.js"
"%scripts%update.js"
) do (
if not exist "%%~a" (
set /a "num+=1"
if !num! gtr 20 set "nofile=!nofile!..." & goto:filelisterr
set "nofile=!nofile!"%%~a" "
)
)
:filelisterr
if defined nofile (
call:clearscreen
title [Error] %name%
if exist "%tmppath%" 1>nul 2>&1 rd /s /q "%tmppath%"
1>&2 echo.%spacebar%
1>&2 echo. Application can not get access to the following files:
1>&2 echo.
for %%j in (%nofile%) do 1>&2 echo. - %%~j
1>&2 echo.
1>&2 echo. Check permissions and try again.
1>&2 echo.%spacebar%
call:dopause
if defined oldtitle title %oldtitle%
exit /b
)
:settemp
set "rnd=%random%"
if not exist "%tmppath%%rnd%\" (
set "tmppath=%tmppath%%rnd%"
1>nul 2>&1 md "%tmppath%%rnd%" || (
call:errormsg "Can not create temporary directory:" "%tmppath%%rnd%!"
exit /b
)
) else (
goto:settemp
)
for %%a in (JPG PNG GIF) do (
set "ImageNum%%a=0"
set "TotalNum%%a=0"
set "TotalNumErr%%a=0"
set "TotalSize%%a=0"
set "STotalSize%%a=0"
set "ImageSize%%a=0"
set "SImageSize%%a=0"
set "change%%a=0"
set "perc%%a=0"
set "step%%a=0"
set "step10%%a=1000"
set "stepB%%a=1"
)
set "png="
set "jpeg="
set "gif="
set "perr="
set "stime="
set "ftime="
set "params="
set "updateurl=http://x128.ho.ua/update.ini"
set "configpath=%~dp0\Tools\config.ini"
set "logfile=%tmppath%\Images"
set "iculog=%tmppath%\icu.log"
set "iculck=%tmppath%\icu.lck"
set "countPNG=%tmppath%\countpng"
set "countJPG=%tmppath%\countjpg"
set "countGIF=%tmppath%\countgif"
set "filelist=%tmppath%\filelist"
set "filelist1=%tmppath%\filelist1"
set "paramfile=%tmppath%\param.txt"
::For Images with characters - %filelisterr%
::For Images are already optimized - %filelisterr%1
::For Images are not supported - %filelisterr%2<num thread>
::For Images are not found - %filelisterr%3<num thread>
set "filelisterr=%tmppath%\filerr"
::Table size
set "TFN=31"
set "KB=1024"
set /a "MB=KB*KB"
set /a "GB=MB*KB"
::restrictions in bytes (default - 100Mb)
set /a "BYTECONV=100*%MB%"
set "thread=" & set "updatecheck=" & set "outdir=" & set "nooutfolder=" & set "perr="
set "jpegtags=" & set "xtreme=" & set "advanced=" & set "pngtags=" & set "giftags="
call:readini "%configpath%"
call:sethread %thread%
set "updatecheck=%update%" & set "update="
if /i "%giftags%" equ "true" (set "giftags=--no-comments --no-extensions --no-names") else (set "giftags=")
call set "outdir=%outdir%"
if defined outdir set oparam="/Outdir:%outdir%"
cscript //nologo //E:JScript "%scripts%pfilter.js" %* %oparam% 1>"%paramfile%" 2>"%filelisterr%"
call:readini "%paramfile%"
if defined perr (
set "perr=%perr:~,-1%"
set "perr=!perr:;=, !"
call:errormsg "Unknown !perr! setting(s^) value."
exit /b
)
if not defined params for %%a in ("%filelisterr%") do if %%~za neq 0 (
1>&2 (
echo.%spacebar%
echo. Unknown parameters:
type "%%~a"
echo.%spacebar%
)
call:errormsg
exit /b
)
1>nul 2>&1 del /f/q "%paramfile%"
set "oparam="
call:checkparams %params%
if "%png%" equ "0" if "%jpeg%" equ "0" if "%gif%" equ "0" goto:endsetcounters
if /i "%outdir%" equ "false" (set "outdir=" & set "nooutfolder=yes") else if /i "%outdir%" equ "true" set "outdir="
if not defined nooutfolder if not defined outdir (
call:clearscreen
title [Loading] %name%
for /f "tokens=* delims=" %%a in ('browsefolder.exe /CurPath:desktop /Title:"Image Catalyst" /Description:"Choose directory to save images to. Click 'Cancel' to replace original images with optimized versions." /block:window /center:window /flag:81') do set "outdir=%%~a"
)
if defined outdir (
if "!outdir:~-1!" neq "\" set "outdir=!outdir!\"
if not exist "!outdir!" (
1>nul 2>&1 md "!outdir!" || (
call:errormsg "Can not create directory for optimized files:" "!outdir!"
exit /b
)))
title [Loading] %name%
call:clearscreen
echo.%spacebar%
echo. Loading. Please wait...
echo.%spacebar%
1>nul 2>&1 del /f /q "%filelist%"
for %%a in (%params%) do (
call:makefilelist %%a 1>"%filelist1%" 2>>"%filelisterr%"
for %%b in ("%filelist1%") do if "%%~zb" neq "0" (
cscript //nologo //E:JScript "%scripts%filter.js" "/BasePath:%%~a" <"%filelist1%" 1>>"%filelist%" 2>>"%filelisterr%"
))
:setcounters
if exist "%filelist%" (
if "%png%" neq "0" for /f "tokens=*" %%a in ('findstr /i /e ".png" "%filelist%" ^| find /i /c ".png" 2^>nul') do set /a "TotalNumPNG+=%%a"
if "%jpeg%" neq "0" for /f "tokens=*" %%a in ('findstr /i /e ".jpg" "%filelist%" ^| find /i /c ".jpg" 2^>nul') do set /a "TotalNumJPG+=%%a"
if "%jpeg%" neq "0" for /f "tokens=*" %%a in ('findstr /i /e ".jpe" "%filelist%" ^| find /i /c ".jpe" 2^>nul') do set /a "TotalNumJPG+=%%a"
if "%jpeg%" neq "0" for /f "tokens=*" %%a in ('findstr /i /e ".jpeg" "%filelist%" ^| find /i /c ".jpeg" 2^>nul') do set /a "TotalNumJPG+=%%a"
if "%gif%" neq "0" for /f "tokens=*" %%a in ('findstr /i /e ".gif" "%filelist%" ^| find /i /c ".gif" 2^>nul') do set /a "TotalNumGIF+=%%a"
)
if %TotalNumPNG% gtr 0 (if not defined png call:png) else set "png=0"
if %TotalNumJPG% gtr 0 (if not defined jpeg call:jpeg) else set "jpeg=0"
if %TotalNumGIF% gtr 0 (if not defined gif call:gif) else set "gif=0"
if exist "%filelisterr%" (
if defined png for /f "tokens=* delims=" %%a in ('findstr /i /e ".png" "%filelisterr%" ^| find /i /c ".png" 2^>nul') do set /a "TotalNumErrPNG+=%%a"
if defined jpeg for /f "tokens=* delims=" %%a in ('findstr /i /e ".jpg" "%filelisterr%" ^| find /i /c ".jpg" 2^>nul') do set /a "TotalNumErrJPG+=%%a"
if defined jpeg for /f "tokens=* delims=" %%a in ('findstr /i /e ".jpe" "%filelisterr%" ^| find /i /c ".jpe" 2^>nul') do set /a "TotalNumErrJPG+=%%a"
if defined jpeg for /f "tokens=* delims=" %%a in ('findstr /i /e ".jpeg" "%filelisterr%" ^| find /i /c ".jpeg" 2^>nul') do set /a "TotalNumErrJPG+=%%a"
if defined gif for /f "tokens=* delims=" %%a in ('findstr /i /e ".gif" "%filelisterr%" ^| find /i /c ".gif" 2^>nul') do set /a "TotalNumErrGIF+=%%a"
)
:endsetcounters
if %TotalNumPNG% equ 0 if %TotalNumJPG% equ 0 if %TotalNumGIF% equ 0 (
call:clearscreen
call:errormsg "No images found. Please check input and try again."
exit /b
)
call:runningcheck "%name% %version%"
::echo.This process is work&pause & title %oldtitle%&exit /b
for /l %%a in (1,1,%thread%) do (
if "%png%" neq "0" >"%logfile%png.%%a" echo.
if "%jpeg%" neq "0" >"%logfile%jpg.%%a" echo.
if "%gif%" neq "0" >"%logfile%gif.%%a" echo.
)
call:clearscreen
echo.%spacebar%
echo. File Name ^| Original ^| Optimized ^| Savings ^| %% Savings
echo. ^| Size ^| Size ^| ^|
echo.%spacebar%
if /i "%updatecheck%" equ "true" start "" /b cmd.exe /c ""%fullname%" updateic"
call:setitle
call:setvtime stime
for /f "usebackq tokens=1,2 delims= " %%a in ("%filelist%") do (
call:initsource "%%~a"
if defined ispng if "%png%" neq "0" call:filework "%%~fa" "%%~fb" png %thread% ImageNumPNG
if defined isjpeg if "%jpeg%" neq "0" call:filework "%%~fa" "%%~fb" jpg %thread% ImageNumJPG
if defined isgif if "%gif%" neq "0" call:filework "%%~fa" "%%~fb" gif %thread% ImageNumGIF
)
:waithread
call:waitflag "%tmppath%\thrt*.lck"
for /l %%z in (1,1,%thread%) do (
call:typelog png %%z
call:typelog jpg %%z
call:typelog gif %%z
)
echo.%spacebar%
call:setitle "%name%"
call:end
call:dopause
if defined oldtitle title %oldtitle%
exit /b
:checkparams
set "ispng=%png%" & set "isjpeg=%jpeg%" & set "isgif=%gif%"
:checkparams1
if "%~1" equ "" (
if /i "%ispng%" equ "yes" (call:png) else if not defined png set "png=0"
if /i "%isjpeg%" equ "yes" (call:jpeg) else if not defined jpeg set "jpeg=0"
if /i "%isgif%" equ "yes" (call:gif) else if not defined gif set "gif=0"
set "ispng=" & set "isjpeg=" & set "isgif="
exit /b
)
set "p=%~1"
if exist "%p:~1%" (
if /i "%p:~,1%" equ "f" call:checkfile "%p:~1%"
if /i "%p:~,1%" equ "d" call:checkdir "%p:~1%"
)
shift
goto:checkparams1
:checkfile
if not defined ispng if /i "%~x1" equ ".png" set "ispng=yes"
if not defined isjpeg (
if /i "%~x1" equ ".jpg" set "isjpeg=yes"
if /i "%~x1" equ ".jpe" set "isjpeg=yes"
if /i "%~x1" equ ".jpeg" set "isjpeg=yes"
)
if not defined isgif if /i "%~x1" equ ".gif" set "isgif=yes"
exit /b
:checkdir
if not defined ispng call:checkmask %1 "*.png" && set "ispng=yes"
if not defined isjpeg call:checkmask %1 ""*.jpg" "*.jpe?"" && set "isjpeg=yes"
if not defined isgif call:checkmask %1 "*.gif" && set "isgif=yes"
exit /b
:checkmask
for /r "%~1" %%i in (%~2) do exit /b 0
exit /b 1
:makefilelist
if "%~1" equ "" exit /b
set "p=%~1"
if exist "%p:~1%" (
if /i "%p:~,1%" equ "f" echo.%p:~1%
if /i "%p:~,1%" equ "d" call:dir2list "%p:~1%"
)
shift
goto:checkparams
:dir2list
setlocal
set "mask="
if "%jpeg%" neq "0" set mask="%~1\*.jpg" "%~1\*.jpe?"
if "%png%" neq "0" set mask=%mask% "%~1\*.png"
if "%gif%" neq "0" set mask=%mask% "%~1\*.gif"
if not defined mask exit /b
dir /a-d /b /s %mask%
endlocal
exit /b
:runningcheck
title [Waiting] %name%
setlocal
call:runic "%~1"
if %runic% gtr 0 (
call:clearscreen
echo.%spacebar%
echo. Another process %name% is running.
echo.
echo. Waiting for it to shut down or press any key.
echo.%spacebar%
:: call:runningcheck2 "%~1"
call:runic2 "%~1"
)
endlocal
title %name%
exit /b 0
:runningcheck2
2>nul (5>"%iclock%" call:runic2 "%~1" || (
call:waitpresskey %errortimewait% || exit /b 1
goto:runningcheck2
))
exit /b 0
:runic2
call:waitpresskey %errortimewait% || exit /b 0
call:runic "%~1"
if %runic% gtr 0 goto:runic2
exit /b 0
:runic
for /f "tokens=* delims=" %%a in ('tasklist /fo csv /v /nh /fi "IMAGENAME eq cmd.exe" ^| find /i /c "%~1" ') do (
set "runic=%%a"
)
exit /b
:setvtime
set "%1=%date% %time:~0,2%:%time:~3,2%:%time:~6,2%"
exit /b
:icupdate
if not exist "%scripts%update.js" exit /b
>"%iculck%" echo.Update IC
cscript //nologo //E:JScript "%scripts%update.js" %updateurl% 2>nul 1>"%iculog%" || 1>nul 2>&1 del /f /q "%iculog%"
1>nul 2>&1 del /f /q "%iculck%"
exit /b
::%1 - png | jpg | gif
::%2 - %thread%
::%3 - input file
::%4 - output file
:createthread
if %2 equ 1 call:threadwork %1 1 %3 %4 & call:typelog %1 1 & exit /b
for /l %%z in (1,1,%2) do (
if not exist "%tmppath%\thrt%%z.lck" (
call:typelog %1 %%z
>"%tmppath%\thrt%%z.lck" echo. Image processing: %3
start /b /LOW /MIN cmd.exe /s /c ""%fullname%" thrd "%~3" "%~4" %1 %%z"
exit /b
)
)
call:waitrandom 500
goto:createthread
::%1 - png | jpg | gif
::%2 - thread number
:typelog
if %thread% equ 1 exit /b
if not defined typenum%~1%~2 set "typenum%~1%~2=1"
if not exist "%logfile%%1.%2" exit /b
set "tmpskip=!typenum%~1%~2!"
for /f "usebackq skip=%tmpskip% tokens=1-5 delims=;" %%b in ("%logfile%%1.%2") do (
call:stepcalc %~1 %%c %%d
call:printfileinfo "%%~b" %%c %%d %%e %%f %~1
set /a "typenum%~1%~2+=1"
)
exit /b
::%1 - file name
::%2 - original size in byte
::%3 - optimize size in byte
::%4 - change (%2 - %3)
::%5 - percent change (%4*100/%2)
::%6 - png | jpg | gif
:printfileinfo
setlocal
set "fn="
call:cropfilename fn "%~1" %TFN%
set "origsize=%~2"
set "optsize=%~3"
set "measure="
call:prepsize origsize measure
call:prepsize2 optsize measure
set "origsize= %origsize% %measure%"
set "optsize= %optsize% %measure%"
set "change=%~4"
set "origsize2=%~2"
call:prepsize change measure
call:prepsize2 origsize2 measure
call:perccalc %origsize2:.=% %change:.=% percent
set "change= %change% %measure%"
set "percent= %percent%%%"
echo. !fn:~,%TFN%!^|%origsize:~-10%^|%optsize:~-11%^|%change:~-11%^|%percent:~-10%
endlocal
exit /b
::%1 - variable name for number (in/out)
::%2 - variable name for measure (out)
:prepsize
setlocal
set "var=!%~1!"
set "sign="
if "%var:~,1%" equ "-" (set "sign=-" & set "var=%var:~1%")
set "meas=B"
if %var% geq %GB% (set "meas=GB" & goto:GBprepsize)
if %var% geq %MB% (set "meas=MB" & goto:MBprepsize)
if %var% geq %KB% (set "meas=KB" & goto:KBprepsize)
goto:finprepsize
::%1 - variable name for number (in/out)
::%2 - variable name for measure (in/out)
:prepsize2
if not defined %~2 exit /b
setlocal
set "var=!%~1!"
set "sign="
if "%var:~,1%" equ "-" (set "sign=-" & set "var=%var:~1%")
set "meas=!%~2!"
if "%meas%" equ "KB" goto:KBprepsize
if "%meas%" equ "B" goto:finprepsize
if "%meas%" equ "MB" goto:MBprepsize
if "%meas%" equ "GB" goto:GBprepsize
goto:finprepsize
:GBprepsize
call:division var %GB% 100 & goto:finprepsize
:MBprepsize
call:division var %MB% 100 & goto:finprepsize
:KBprepsize
call:division var %KB% 100 & goto:finprepsize
:Bprepsize
call:division var 1 100
:finprepsize
endlocal & set "%~1=%sign%%var%" & set "%~2=%meas%"
exit /b
::%1 - number of 100%
::%2 - number, which is necessary to calculate the percentage
::%3 - variable name for save result
:perccalc
setlocal
::echo.%~0: %*
set "change=%~2"
set "sign="
if "%change:~,1%" equ "-" (set "sign=-" & set "change=%change:~1%")
set /a "perc=%change%*100/%~1" 2>nul
set /a "fract=%change%*100%%%~1*100/%~1" 2>nul
set /a "perc=%perc%*100+%fract%"
call:division perc 100 100
endlocal & set "%~3=%sign%%perc%"
exit /b
::%1 - file name
::%2 - error message
:printfileerr
setlocal
set "fn=%~nx1 "
set "errmsg=%~2"
call:centerstring errmsg 45
1>&2 echo. %fn:~,30%^|%errmsg%
endlocal
exit /b
::%1 - variable containing file name
::%2 - file name in %1
::%3 - max length file name
:cropfilename
setlocal
set "xfn=%~nx2"
set "xfnext=%~x2"
set "xfnlen=0"
set "xfnextlen=0"
call:strlen xfn xfnlen
call:strlen xfnext xfnextlen
set /a "xfnextlen=%3-%xfnextlen%-2"
if %xfnlen% gtr %3 (
call set "xfn=%%xfn:~,%xfnextlen%%%..%xfnext%"
) else (
set "xfn=%xfn% "
set "xfn=!xfn:~,%3!"
)
endlocal & set "%~1=%xfn%"
exit /b
:centerstring StrVar Length
if "%~1" equ "" exit /b
if not defined %~1 exit /b
setlocal
set "xstringlen=0"
set "xstr=!%~1!"
call:strlen xstr xstringlen
set "xstradd= "
set /a "xstraddlen=(%~2-%xstringlen%)/2"
set "xstradd=!xstradd:~,%xstraddlen%!"
if %xstringlen% geq %~2 (
set "xstr=!xstr:~,%~2!"
) else (
set "xstr=!xstradd!%xstr%!xstradd!"
set /a "xstraddlen=xstringlen+xstraddlen*2"
if !xstraddlen! lss %~2 set "xstr= !xstr!"
)
endlocal & set "%~1=%xstr%"
exit /b
::original: http://forum.script-coding.com/viewtopic.php?pid=71000#p71000
:strlen StrVar RtnVar -- be sure to check if the returned errorlevel is 0
setlocal
set /a "}=0"
if "%~1" neq "" if defined %~1 (
for %%# in (4096 2048 1024 512 256 128 64 32 16) do (
if "!%~1:~%%#,1!" neq "" set "%~1=!%~1:~%%#!" & set /a "}+=%%#"
)
set "%~1=!%~1!0FEDCBA9876543211" & set /a "}+=0x!%~1:~32,1!!%~1:~16,1!"
)
)
endlocal & set /a "%~2=%}%"
exit /b
::%1 - png | jpg | gif
::%2 - thread number
::%3 - input file
::%4 - output file
:threadwork
1>nul 2>&1 md "%~dp4"
if /i "%1" equ "png" call:pngfilework %2 %3 %4 & if %thread% gtr 1 >>"%countPNG%.%2" echo.1
if /i "%1" equ "jpg" call:jpegfilework %2 %3 %4 & if %thread% gtr 1 >>"%countJPG%.%2" echo.1
if /i "%1" equ "gif" call:giffilework %2 %3 %4 & if %thread% gtr 1 >>"%countGIF%.%2" echo.1
if exist "%tmppath%\thrt%2.lck" >nul 2>&1 del /f /q "%tmppath%\thrt%2.lck"
exit /b
:waitflag
if not exist "%~1" exit /b
call:waitrandom 2000
goto:waitflag
:waitrandom2
setlocal
if not defined istimeout (call:waitrandom %~1 & exit /b)
set "ww=%~1"
if %~1 lss 1000 set "ww=1000"
set /a "ww=%random%%%(%ww%/1000)"
1>nul 2>&1 timeout /t %ww%
endlocal & exit /b
:waitrandom
setlocal
set /a "ww=%random%%%%1"
1>nul 2>&1 ping -n 1 -w %ww% 127.255.255.255
endlocal & exit /b
::If press key return errorlevel=1. If timeout - errorlevel=0
:waitpresskey
setlocal
set "ww=%~1"
if defined istimeout (
if %ww% lss 1000 set "ww=1000"
timeout /t !ww:~,-3! 2>nul | 1>nul 2>&1 findstr /e "0" || (endlocal & exit /b 1)
) else call:waitrandom %ww%
endlocal & exit /b 0
:initsource
set "isjpeg="
set "ispng="
set "isgif="
if /i "%~x1" equ ".png" set "ispng=1"
if /i "%~x1" equ ".jpg" set "isjpeg=1"
if /i "%~x1" equ ".jpeg" set "isjpeg=1"
if /i "%~x1" equ ".jpe" set "isjpeg=1"
if /i "%~x1" equ ".gif" set "isgif=1"
exit /b
:sethread
set /a "thread=%~1+1-1"
if "%~1" neq "" if "%~1" neq "0" set "thread=%~1" & exit /b
if %thread% equ 0 set "thread=%NUMBER_OF_PROCESSORS%"
exit /b
:png
call:clearscreen
set "png="
title [PNG] %name%
echo. ----------------------
echo. PNG optimization mode:
echo. ----------------------
echo.
echo. [1] Advanced
echo.
echo. [2] Xtreme
echo.
echo. [0] Skip
echo.
echo. ------------------------------------
set /p png="#Select mode and press Enter [0-2]: "
echo. ------------------------------------
echo.
if "%png%" neq "0" if "%png%" neq "1" if "%png%" neq "2" goto:png
exit /b
:jpeg
call:clearscreen
set "jpeg="
title [JPEG] %name%
echo. ----------------------
echo. JPEG otimization mode:
echo. ----------------------
echo.
echo. [1] Baseline
echo.
echo. [2] Progressive
echo.
echo. [3] Default
echo.
echo. [0] Skip
echo.
echo. ------------------------------------
set /p jpeg="#Select mode and press Enter [0-3]: "
echo. ------------------------------------
echo.
if "%jpeg%" neq "0" if "%jpeg%" neq "1" if "%jpeg%" neq "2" if "%jpeg%" neq "3" goto:jpeg
exit /b
:gif
call:clearscreen
set "gif="
title [GIF] %name%
echo. ----------------------
echo. GIF optimization mode:
echo. ----------------------
echo.
echo. [1] Default
echo.
echo. [0] Skip
echo.
echo. ------------------------------------
set /p gif="#Select mode and press Enter [0-1]: "
echo.
echo.
if "%gif%" neq "0" if "%gif%" neq "1" goto:gif
exit /b
:setitle
if "%jpeg%" equ "0" if "%png%" equ "0" if "%gif%" equ "0" (title %~1%name% & exit /b)
if %thread% gtr 1 (
set "ImageNumPNG=0" & set "ImageNumJPG=0" & set "ImageNumGIF=0"
for /l %%c in (1,1,%thread%) do (
for %%b in ("%countPNG%.%%c") do set /a "ImageNumPNG+=%%~zb/3" 2>nul
for %%b in ("%countJPG%.%%c") do set /a "ImageNumJPG+=%%~zb/3" 2>nul
for %%b in ("%countGIF%.%%c") do set /a "ImageNumGIF+=%%~zb/3" 2>nul
)
)
setlocal
if "%~1" equ "" (set "fintitle=%name% %version%") else (set "fintitle=%~1")
if %png% equ 1 (set "pngtitle=Advanced")
if %png% equ 2 (set "pngtitle=Xtreme")
if %jpeg% equ 1 (set "jpegtitle=Baseline")
if %jpeg% equ 2 (set "jpegtitle=Progressive")
if %jpeg% equ 3 (set "jpegtitle=Default")
if %gif% equ 1 (set "giftitle=Default")
set "titlestr="
set "tmpn=0"
if %png% gtr 0 (
set /a "perc=%ImageNumPNG%*100/%TotalNumPNG%"
set "titlestr=PNG %pngtitle%: !perc!%%"
)
if %jpeg% gtr 0 (
set /a "perc=%ImageNumJPG%*100/%TotalNumJPG%"
if %png% gtr 0 set "titlestr=%titlestr% ^| "
set "titlestr=!titlestr!JPG %jpegtitle%: !perc!%%"
)
if %gif% gtr 0 (
set /a "perc=%ImageNumGIF%*100/%TotalNumGIF%"
set /a "tmpn=%jpeg%+%png%"
if !tmpn! gtr 0 (set "titlestr=%titlestr% ^| ")
set "titlestr=!titlestr!GIF %giftitle%: !perc!%%"
)
title [%titlestr%] %fintitle%
endlocal & exit /b
::%1 - input file
::%2 - output file
::%3 - png | jpg | gif
::%4 - %thread%
::%5 - ImageNum(PNG|JPG|GIF)
:filework
call:createthread %3 %4 "%~f1" "%~f2"
set /a "%5+=1"
call:setitle
exit /b
::%1 - thread number
::%2 - input file
::%3 - output file
:pngfilework
set "zc="
set "zm="
set "zs="
set "iter=10"
set "psize=%~z2"
set "errbackup=0"
set "logfile2=%logfile%png.%1"
set "pnglog=%tmppath%\png%1.log"
set "filework=%tmppath%\%~n2-ic%1%~x2"
if not exist "%~2" (
call:saverrorlog "%~f2" 3 %~1 PNG
exit /b 1
)
if %png% equ 2 (
>"%pnglog%" 2>nul truepng -y -i0 -zw7 -zc7 -zm5-9 -zs0,1,3 -f0,5 -fs:1 %xtreme% -force -out "%filework%" "%~2"
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 PNG & goto:pngfwe)
for /f "tokens=2,4,6,8,10 delims=: " %%a in ('findstr /r /i /b /c:"zc:..zm:..zs:" "%pnglog%" 2^>nul') do (
set "zc=%%a"
set "zm=%%b"
set "zs=%%c"
)
if !zs! gtr 1 (
set "zs=1"
set "iter=15"
)
1>nul 2>&1 pngwolfzopfli --zopfli-iter=!iter! --zopfli-maxsplit=0 --zlib-window=15 --zlib-level=!zc! --zlib-memlevel=!zm! --zlib-strategy=!zs! --max-stagnate-time=0 --max-evaluations=1 --in="%filework%" --out="%filework%"
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 PNG & goto:pngfwe)
)
if %png% equ 1 (
1>nul 2>&1 truepng -y -i0 -zw7 -zc7 -zm8 -zs0,1,3 -f0,5 -fs:1 %advanced% -force -out "%filework%" "%~2"
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 PNG & goto:pngfwe)
1>nul 2>&1 deflopt -k "%filework%"
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 PNG & goto:pngfwe)
1>nul 2>&1 advdef -z2 "%filework%"
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 PNG & goto:pngfwe)
)
1>nul 2>&1 deflopt -k "%filework%"
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 PNG & goto:pngfwe)
call:backup2 "%~f2" "%filework%" "%~f3" || set "errbackup=1"
if %errbackup% neq 0 (call:saverrorlog "%~f2" 2 %~1 PNG & goto:pngfwe)
if /i "%pngtags%" equ "true" (1>nul 2>&1 truepng -nz -md remove all "%~3" || (call:saverrorlog "%~f2" 2 %~1 PNG & goto:pngfwe))
call:savelog "%~f3" %psize%
if %thread% equ 1 for %%a in ("%~f3") do (set /a "ImageSizePNG+=%%~za" & set /a "TotalSizePNG+=%psize%")
:pngfwe
1>nul 2>&1 del /f /q "%filework%" "%pnglog%"
exit /b
::%1 - thread number
::%2 - input file
::%3 - output file
:jpegfilework
set "ep="
set "jsize=%~z2"
set "errbackup=0"
set "logfile2=%logfile%jpg.%1"
set "jpglog=%tmppath%\jpg%1.log"
if /i "%~f2" equ "%~f3" (
set "filework=%tmppath%\%~n2-ic%1%~x2"
) else (
set "filework=%~f3"
)
if not exist "%~2" (
call:saverrorlog "%~f2" 3 %~1 JPG
exit /b 1
)
if %jpeg% equ 1 (
jpegtran -verbose -revert -optimize -copy all -outfile "%filework%" "%~2" 1>"%jpglog%" 2>&1
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 JPG & goto:jpegfwe)
for /f "tokens=4,10 delims=:,= " %%a in ('findstr /C:"Start Of Frame" "%jpglog%" 2^>nul') do (set "ep=%%a")
if "!ep!" equ "0xc0" goto:jpegfwb
if "!ep!" equ "0xc2" (
if /i "%~f2" equ "%~f3" (1>nul 2>&1 move /y "%filework%" "%~f3" || set "errbackup=1")
goto:jpegfwf
) else (
call:saverrorlog "%~f2" 2 %~1 JPG & goto:jpegfwe
)
)
if %jpeg% equ 2 (
jpegtran -verbose -copy all -outfile "%filework%" "%~2" 1>"%jpglog%" 2>&1
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 JPG & goto:jpegfwe)
for /f "tokens=4,10 delims=:,= " %%a in ('findstr /C:"Start Of Frame" "%jpglog%" 2^>nul') do (set "ep=%%a")
if "!ep!" equ "0xc2" goto:jpegfwb
if "!ep!" equ "0xc0" (
if /i "%~f2" equ "%~f3" (1>nul 2>&1 move /y "%filework%" "%~f3" || set "errbackup=1")
goto:jpegfwf
) else (
call:saverrorlog "%~f2" 2 %~1 JPG & goto:jpegfwe
)
)
if %jpeg% equ 3 (
jpginfo "%~2" 1>"%jpglog%" 2>&1
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 JPG & goto:jpegfwe)
for /f "usebackq tokens=5" %%a in ("%jpglog%") do set "ep=%%~a"
if /i "!ep!" equ "Baseline" (
jpegtran -verbose -revert -optimize -copy all -outfile "%filework%" "%~2" 1>nul 2>&1 && goto:jpegfwb
)
if /i "!ep!" equ "Progressive" (
jpegtran -verbose -copy all -outfile "%filework%" "%~2" 1>nul 2>&1 && goto:jpegfwb
)
call:saverrorlog "%~f2" 2 %~1 JPG & goto:jpegfwe
)
:jpegfwb
if /i "%~f2" neq "%~f3" (
call:backup "%filework%" "%~f2" >nul || set "errbackup=1"
) else (
call:backup "%~f2" "%filework%" true >nul || set "errbackup=1"
)
:jpegfwf
1>nul 2>&1 del /f /q "%jpglog%"
if %errbackup% neq 0 (call:saverrorlog "%~f2" 3 %~1 JPG & goto:jpegfwe)
if /i "%jpegtags%" equ "true" (1>nul 2>&1 jpegstripper -y "%~f3" || (call:saverrorlog "%~f2" 2 %~1 JPG & exit /b))
call:savelog "%~f3" %jsize%
if %thread% equ 1 for %%a in ("%~f3") do (set /a "ImageSizeJPG+=%%~za" & set /a "TotalSizeJPG+=%jsize%")
exit /b
:jpegfwe
if /i "%~f2" neq "%~f3" (1>nul 2>&1 del /f /q "%filework%")
1>nul 2>&1 del /f /q "%jpglog%"
exit /b 1
::%1 - thread number
::%2 - input file
::%3 - output file
:giffilework
set "gsize=%~z2"
set "errbackup=0"
set "logfile2=%logfile%gif.%1"
set "filework="
if /i "%~f2" equ "%~f3" (
set "filework1=%tmppath%\%~n2%1%-gifsicle1~x1"
set "filework=!filework1! "
) else (
set "filework1=%~f3"
)
set "filework2=%tmppath%\%~n2%1%-gifsicle2~x1"
set "filework=%filework%%filework2%"
if not exist "%~2" (
call:saverrorlog "%~f2" 3 %~1 GIF
exit /b 1
)
gifsicle --batch %giftags% --optimize=0 --output "%filework1%" "%~2" 1>nul 2>&1
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 GIF & goto:giffwe)
gifsicle --batch %giftags% --optimize=3 --output "%filework2%" "%~2" 1>nul 2>&1
if errorlevel 1 (call:saverrorlog "%~f2" 2 %~1 GIF & goto:giffwe)
if /i "%~f2" neq "%~f3" (
call:backup "%filework1%" "%~f2" >nul || set "errbackup=1"
call:backup "%filework1%" "%filework2%" true >nul || set "errbackup=1"
) else (
call:backup "%~f3" "%filework1%" true >nul || set "errbackup=1"
call:backup "%~f3" "%filework2%" true >nul || set "errbackup=1"
)
if %errbackup% neq 0 (call:saverrorlog "%~f2" 3 %~1 GIF & goto:giffwe)
call:savelog "%~f3" %gsize%
if %thread% equ 1 for %%a in ("%~f3") do (set /a "ImageSizeGIF+=%%~za" & set /a "TotalSizeGIF+=%jsize%")
exit /b
:giffwe
if /i "%~f2" neq "%~f3" if exist "%filework1%" del /f /q "%filework1%"
if exist "%filework2%" del /f /q "%filework2%"
exit /b 1
:backup
if not exist "%~1" exit /b 2
if not exist "%~2" exit /b 3
if %~z2 equ 0 (if "%3" neq "" (1>nul 2>&1 del /f /q "%~2") & exit /b 4)
if %~z1 leq %~z2 (
if "%3" neq "" (1>nul 2>&1 del /f /q "%~2")
) else (
1>nul 2>&1 copy /b /y "%~2" "%~1" || exit /b 1
if "%3" neq "" 1>nul 2>&1 del /f /q "%~2"
)
exit /b
:backup2
if not exist "%~1" exit /b 2
if not exist "%~2" exit /b 3
set "cone="
if %~z2 equ 0 set "cone=yes"
if %~z1 leq %~z2 set "cone=yes"
if defined cone (
if "%~1" neq "%~3" (1>nul 2>&1 copy /b /y "%~1" "%~3" || exit /b 1)
) else (
1>nul 2>&1 copy /b /y "%~2" "%~3" || exit /b 1
)
exit /b 0
::%1 - optimize file path
::%2 - original file size
::%3 - thread number
:savelog
setlocal
::echo.%~0[in]: %1 %~2 %~z1
set /a "change=%~z1-%~2"
::call:perccalc %~2 %change% perc
set /a "change=%~z1-%~2"
>>"%logfile2%" echo.%~1;%~2;%~z1;%change%;0.00;ok
if %thread% equ 1 (
call:printfileinfo "%~1" %2 %~z1 %change% 0.00
)
endlocal
exit /b
::%1 - file name
::%2 - 1 - Images are already optimized
:: 2 - Images are not supported
:: 3 - Images are not found
::%3 - thread number
::%4 - JPG|PNG|GIF
:saverrorlog
if exist "%filework%" 1>nul 2>&1 del /f /q "%filework%"
if "%~2" equ "" exit /b
>>"%filelisterr%%~2%~3" echo. %~f1
if %thread% equ 1 (call:printfileerr "%~f1" %~2)
exit /b
::%1 - variable name for division (dividend)
::%2 - divider
::%3 - 10^(number of decimal places) - (100 - 2 decimal places, 1000 - 3 decimal places, 1 - no decimals places)
::Return: float value with %3 decimal places: %1=!%1!/%2
:division
setlocal
1>nul 2>&1 set /a "int=!%1!/%2"
if %~3 equ 1 (
endlocal & set "%1=%int%" & exit /b
exit /b
)
1>nul 2>&1 set /a "fractd=!%1!%%%2*%3/%2"
if "%fractd:~,1%" equ "-" (set "fractd=%fractd:~1%")
1>nul 2>&1 set /a "fractd=%3+%fractd%"
endlocal & set "%1=%int%.%fractd:~1%"
exit /b
::%1 - variable name for division (dividend)
::%2 - divider
::%3 - 10^(number of decimal places) - (100 - 2 decimal places, 1000 - 3 decimal places, 1 - no decimals places)
::Return: integer value: %1=!%1!/%2*%3
:division2
::echo.%~0[in]: %~1=!%~1! %~2 %~3
setlocal
1>nul 2>&1 set /a "int=!%~1!/%~2"
if %~3 equ 1 (
endlocal & set "%~1=%int%" & exit /b
exit /b
)
1>nul 2>&1 set /a "fractd=!%~1!%%%~2*%~3/%~2"
endlocal & set /a "%~1=%int%*%~3+(%fractd%)"
::echo.%~0[out]: !%~1!
exit /b
:end
call:setvtime ftime
if %jpeg% equ 0 if %png% equ 0 if %gif% equ 0 1>nul 2>&1 ping -n 1 -w 500 127.255.255.255 & goto:finmessage
set /a "TotalNumPNG+=TotalNumErrPNG"
set /a "TotalNumJPG+=TotalNumErrJPG"
set /a "TotalNumGIF+=TotalNumErrGIF"
for %%b in ("%filelisterr%2" "%filelisterr%3") do (
for /f "tokens=1" %%a in ('findstr /e /i /c:".png" "%%~b*" 2^>nul ^| find /i /c ".png" 2^>nul') do (
set /a "TotalNumErrPNG+=%%a"
)
for /f "tokens=1" %%a in ('findstr /e /i /c:".jpg" "%%~b*" 2^>nul ^| find /i /c ".jpg" 2^>nul') do (
set /a "TotalNumErrJPG+=%%a"
)
for /f "tokens=1" %%a in ('findstr /e /i /c:".jpe" "%%~b*" 2^>nul ^| find /i /c ".jpe" 2^>nul') do (
set /a "TotalNumErrJPG+=%%a"
)
for /f "tokens=1" %%a in ('findstr /e /i /c:".jpeg" "%%~b*" 2^>nul ^| find /i /c ".jpeg" 2^>nul') do (
set /a "TotalNumErrJPG+=%%a"
)
for /f "tokens=1" %%a in ('findstr /e /i /c:".gif" "%%~b*" 2^>nul ^| find /i /c ".gif" 2^>nul') do (
set /a "TotalNumErrGIF+=%%a"
)
)
set /a "TotalNumErr=%TotalNumErrPNG%+%TotalNumErrJPG%+%TotalNumErrGIF%"
if %TotalNumErr% gtr 0 (
echo.
echo. Error
set "isfirst="
for %%a in ("%filelisterr%2*") do if %%~za gtr 0 (
if not defined isfirst (
echo.%spacebar%
echo.
echo. Images are not supported:
set "isfirst=1"
)
type "%%~a"
)
set "isfirst="
for %%a in ("%filelisterr%3*") do if %%~za gtr 0 (
if not defined isfirst (
echo.%spacebar%
echo.
echo. Images are not found:
set "isfirst=1"
)
type "%%~a"