build.gradle

plugins {
  id 'org.jetbrains.intellij' version '0.2.0'
}

description = 'Gosu Typeloader :: IJ Plugin'

sourceCompatibility = 1.8
targetCompatibility = 1.8

tasks.withType(JavaCompile) {
  options.encoding = 'UTF-8'
}

repositories {
  mavenLocal()
  mavenCentral()
  maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
}

dependencies {
  compile group: 'org.gosu-lang.gosu', name: 'gosu-core-api', version: gosuVersion
  compile group: 'org.gosu-lang.gosu.managed', name: 'gw-asm-all', version: '5.0.4'
  compile group: 'com.google.guava', name: 'guava', version: '12.0'
  compile group: 'org.gosu-lang', name: 'manifold', version: manifoldVersion
  runtime group: 'org.gosu-lang.gosu', name: 'gosu-core', version: gosuVersion
}

compileJava {
  options.compilerArgs << '-proc:none'
}

afterEvaluate {
  task downloadDependencies(type: Exec) {
    configurations.testRuntime.files
    commandLine 'echo', 'Downloaded all dependencies'
  }
}

intellij {
  pluginName project.name
  version '15.0.6' // Ordinarily, just use the version number: '15.0.6' or '2016.3'. Alternatively, the precise API level is OK too: 'IC-143.2370.31'
  plugins = ['com.guidewire.gosu:4.1.1.9',
             'ASM Bytecode Outline:0.3.5'] //include ASM in the sandbox by default. Nice. 

  //if running on CI, don't download sources
  if(System.getenv('CI') != null) {
    downloadSources false
  }
}

patchPluginXml {
  sinceBuild '141.1010'
  pluginDescription 'IntelliJ IDEA plugin for Gosu language custom types'
}