Ctrl-r for shell history but also bulk select and remove from history

[rieje]

Ctrl-r is super useful for shell history but along with Enter to insert the command to the prompt, I would like (within the same Ctrl-r interface, preferably) to also switch to interface where selecting an entry removes it from history. It should support selecting multiple entries and repeat filtering to select additional entries to remove (only except with e.g. Ctrl-c).

Any ideas on how to implement this if it's not implemented already?

[LangLangBart]

This setup requires 3 things:

• a modified fzf-history-widget
• the assigned FZF_CTRL_R_OPTS environment variable with a complex keybinding for deletion and
  reloading
• assigned HISTFILE, HISTSIZE, and SAVEHIST environment variables

Note

The values assigned to FZF_CTRL_R_OPTS can also be incorporated into the modified
fzf-history-widget. However, I found this method simpler to avoid complications with quotation
marks.

If you place everything in your .zshrc, after sourcing the fzf/shell/key-bindings.zsh file,
it should work seamlessly. The history will always be read from your $HISTFILE, thus I also set
these options:

setopt INC_APPEND_HISTORY  # Write to the history file immediately, not when the shell exits.
setopt SHARE_HISTORY  # Share history between all sessions.

More details on how the deletion works can be found in: #3522

modified-fzf-history-widget() {
  local selected
  setopt localoptions noglobsubst noposixbuiltins pipefail no_aliases no_bash_rematch 2> /dev/null
  # appends the current shell history buffer to the HISTFILE
  builtin fc -AI $HISTFILE
  # pushes entries from the $HISTFILE onto a stack and uses this history
  builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST
  selected="$(builtin fc -rl 1 |
    awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, "", cmd); if (!seen[cmd]++) print $0 }' |
    FZF_DEFAULT_OPTS="--height ${FZF_TMUX_HEIGHT:-40%} ${FZF_DEFAULT_OPTS-} -n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,ctrl-z:ignore ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} --multi" $(__fzfcmd))"
  local ret=$?
	if [[ -n $selected ]]; then
    if [[ "$selected" =~ ^[[:blank:]]*[[:digit:]]+ ]]; then
	  builtin fc -pa "$HISTFILE"
	  zle vi-fetch-history -n "$MATCH"
    else # selected is a custom query, not from history
      LBUFFER="$selected"
    fi
  fi
  # Read the history from the history file into the history list
  builtin fc -R $HISTFILE
  zle reset-prompt
  return $ret
}
zle -N modified-fzf-history-widget
bindkey "^R" modified-fzf-history-widget


export FZF_CTRL_R_OPTS="$(
	cat <<'FZF_FTW'
--bind "ctrl-d:execute-silent(zsh -ic 'builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST; for i in {+1}; do ignore+=( \"${(b)history[$i]}\" );done;
	HISTORY_IGNORE=\"(${(j:|:)ignore})\";builtin fc -W $HISTFILE')+reload:builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST; builtin fc -rl 1 |
	awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, \"\", cmd); if (!seen[cmd]++) print $0 }'"
--bind 'enter:accept-or-print-query'
--header 'enter select · ^d remove'
--prompt ' Global History > '
FZF_FTW
)"


# 'ZDOTDIR' is a Parameter used by the shell, it refers to the location of your 
# shell startup files (see 'man zshparam')
export HISTFILE="${ZDOTDIR:-$HOME}"/.zsh_history
export HISTSIZE=12000
export SAVEHIST=10000

EDIT: use builtin and read history when exiting fzf widget

[andrevmatos]

I use NixOS with home-manager to set up zsh.
Yes, $HISTFILE is assigned, exists and has a tens of thousands of entries.
$SHELL=/run/current-system/sw/bin/zsh, as per NixOS default for zsh shell. I tried exporting it as SHELL=zsh as well, no change in behavior

[LangLangBart]

Tried to create a simple NixOS setup in a Dockerfile to test if a simplified fzf command with fc runs in there, and it seems to work.

fzf --bind "start:reload:fc -p $HISTFILE;fc -rl 1"

---

Could you modify the Dockerfile to help reproduce the issue for me?

FROM nixos/nix:latest

# Install zsh and fzf
RUN nix-channel --update && \
    nix-env --install --attr nixpkgs.zsh nixpkgs.fzf

ENV SHELL /root/.nix-profile/bin/zsh
ENV HISTFILE /.zsh_history

RUN echo 'fzf --bind "start:reload:fc -p $HISTFILE;fc -rl 1"' >$HISTFILE

# Start zsh
CMD ["zsh", "-l", "-o", "INC_APPEND_HISTORY", "-o", "APPEND_HISTORY", "-o", "SHARE_HISTORY"]

docker build --tag nixos --file Dockerfile_nix .
docker run --interactive --tty --rm nixos:latest

[enoryw]

There's no way to manipulate the shell session history to be able to read and delete from it before it gets written to HISTFILE when the session ends, right? I'm interested in this fzf function but INC_APPEND_HISTORY and SHARE_HISTORY removes context of the history (e.g. with multiple terminal windows doing different things, since history gets added immediately, you no longer see commands grouped together by session in the history).

[mattmc3]

There's no way to manipulate the shell session history to be able to read and delete from it before it gets written to HISTFILE when the session ends, right?

Per the manpages (LESS="-p SHARE_HISTORY" man zshoptions), fc -RI lets you sync history manually when you need it. So, if you don't want to set SHARE_HISTORY, you can easily add a test to modified-fzf-history-widget and sync history if SHARE_HISTORY isn't set with the following statement:

[[ -o SHARE_HISTORY ]] || fc -RI

I'm interested in this fzf function but INC_APPEND_HISTORY and SHARE_HISTORY removes context of the history (e.g. with multiple terminal windows doing different things, since history gets added immediately, you no longer see commands grouped together by session in the history).

If you are worried about setting SHARE_HISTORY losing context, you can use fc -lI to show only commands in the current session, or fc -lL to show only the current session and the $HISTFILE, but not other sessions. fc -l will put an asterisk by commands from other sessions. Using fc properly can help alleviate many of the concerns with sharing history in Zsh. You can read more about fc here: LESS="-p fc" man zshbuiltins

[YasserKa]

Building on @LangLangBart solution; I don't recommend replacing the whole fzf default function, since it might get improved with upcoming features. For instance, his solution doesn't put into consideration the line wrapping feature that got added recently.

The recommended way is to add the lines using awk without dismissing any newly added code. Example:

source <(fzf --zsh \
  | awk '
  /fzf-history-widget\(\)/ { 
  print; 
  flag = 1; 
  next 
}
/setopt/ { 
  print
if (flag) { 
  print "  # appends the current shell history buffer to the HISTFILE";
  print "  builtin fc -AI $HISTFILE";
  print "   # pushes entries from the $HISTFILE onto a stack and uses this history";
  print "  builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST";
} 
next
}
/zle reset-prompt/ { 
if (flag) { 
  print "  # Read the history from the history file into the history list"
  print "  builtin fc -R $HISTFILE"; 
  flag = 0 
} 
}
{ print }
'
)