-
Notifications
You must be signed in to change notification settings - Fork 0
/
ULog.pas
155 lines (139 loc) · 4.2 KB
/
ULog.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
{* Copyright (C) 2009-2011 Karl-Michael Schindler
*
* This file is part of Heat Wizard.
*
* Heat Wizard is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version 3
* of the License, or (at your option) any later version.
*
* Heat Wizard is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with Heat Wizard; see the file COPYING. If not, see
* <http://www.gnu.org/licenses/> or write to the
* Free Software Foundation, Inc.
* 51 Franklin Street, Fifth Floor
* Boston, MA 02110-1301, USA
*
* $URL$
* $Id$
*}
unit ULog;
{$mode objfpc}
{$H+}
interface
uses
SysUtils;
type
TLogger = class
public
constructor Create;
destructor Destroy; override;
procedure Output(const Position, Message: string);
end;
var
Logger: TLogger;
implementation
{$IF Defined(DARWIN)}
uses
MacOSAll;
{$IFEND}
{$I version.inc}
var
LogFile: text;
LogFileName: string;
LogFileDirName: string;
{$IF Defined(DARWIN)}
// This is carbon and should be replaced by cocoa as soon as it is a default part of fpc
// Hint:
// To get the path to this directory use the NSLibraryDirectory search path key with the NSUserDomainMask domain.
function GetPathToUserLibraryFolder: string;
const
PathNameLength = 200;
var
foundRef: FSRef;
Path: CStringPtr;
Error: OSStatus;
begin
Error := FSFindFolder(kUserDomain, kDomainLibraryFolderType, kDontCreateFolder, foundRef);
if Error <> noErr then
begin
writeln ('FSFindFolder Error: ', Error);
exit;
end;
Path := StrAlloc(PathNameLength + 1); // null termination needs one more character
Error := FSRefMakePath(foundRef, Path, PathNameLength);
if Error <> noErr then
begin
writeln ('FSRefMakePath Error (check MacErrors.h): ', Error);
if Error = -2110 then
writeln ('Length of path name is to short. Increase PathNameLength in function GetPathToUserLibraryFolder of unit ULog.');
exit;
end;
writeln (Path);
Result := Path;
end;
{$IFEND}
{$IF Defined(WINDOWS)}
function SetApplicationName: string;
begin
SetApplicationName := 'Heat Wizard';
end;
{$IFEND}
constructor TLogger.Create;
var
Intro: string;
begin
Inherited;
{$IF Defined(DARWIN)}
LogFileDirName := GetPathToUserLibraryFolder + '/Logs/';
LogFileName := 'Heat Wizard.log';
{$ELSEIF Defined(WINDOWS)}
OnGetApplicationName := @SetApplicationName;
LogFileDirName := GetAppConfigDir(false) + '\';
LogFileName := 'Heat Wizard.log';
{$ELSE}
LogFileDirName := GetEnvironmentVariable('HOME') + '/.heatwizard/';
LogFileName := 'heatwizard.log';
{$IFEND}
if not DirectoryExists (LogFileDirName) then
mkdir(LogFileDirName);
LogFileName := LogFileDirName + LogFileName;
Intro := FormatDateTime('yyyy-mm-dd hh:mm:ss.zzz', Now) + ' Heat Wizard[' + IntToStr(GetProcessID) + '] ';
{$I-} // for checking IO error
AssignFile(LogFile, LogFileName);
Rewrite (LogFile);
{$I+}
if IOResult = 0 then
begin
writeln (LogFile, Intro + 'Log file');
writeln (LogFile, Intro + 'Version: ', Version);
writeln (LogFile, Intro + '----------------------------------------------------');
flush (LogFile);
end
else
begin
writeln ('Error when opening log file.');
writeln ('LogFileName: ', LogFileName);
writeln ('Error code: ', IOResult, ' (explanations: rtl.pdf, System unit, 36.9.110 IOResult)');
writeln ('Current directory: ', GetCurrentDir);
end;
end;
procedure TLogger.Output(const Position, Message: string);
var
Intro: string;
begin
Intro := FormatDateTime('yyyy-mm-dd hh:mm:ss.zzz', Now) + ' Heat Wizard[' + IntToStr(GetProcessID) + '] ';
writeln (LogFile, Intro + 'Unit ' + Position + ': ' + Message);
flush (LogFile);
end;
destructor TLogger.Destroy;
begin
Close(LogFile);
Inherited Destroy;
end;
end.