flake.nix

{
  description = "hbrainfuck";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    inputs:
    inputs.flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import inputs.nixpkgs { inherit system; };

        hPkgs = pkgs.haskellPackages;
      in
      {
        formatter = pkgs.nixfmt-rfc-style;

        packages.default =
          let
            rawPackage = pkgs.haskellPackages.callCabal2nix "prop-solveur" ./. { };
          in
          pkgs.lib.pipe rawPackage [

            (
              p:
              p.overrideAttrs (old: {
                nativeBuildInputs = (old.nativeBuildInputs or [ ]) ++ [ pkgs.installShellFiles ];
                postInstall =
                  (old.postInstall or "")
                  + ''
                    installShellCompletion --cmd hbf \
                        --bash <("$out/bin/hbf" --bash-completion-script "$out/bin/hbf") \
                        --fish <("$out/bin/hbf" --fish-completion-script "$out/bin/hbf") \
                        --zsh  <("$out/bin/hbf" --zsh-completion-script  "$out/bin/hbf")
                  '';
              })
            )

            pkgs.haskell.lib.justStaticExecutables
          ];

        devShells.default = pkgs.mkShell {
          packages = [
            hPkgs.ghc
            pkgs.cabal-install
            hPkgs.cabal-fmt
            hPkgs.haskell-language-server
            hPkgs.fourmolu
          ];
        };

      }
    );

}