build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.9.22'
    id 'fabric-loom' version '1.5.7'
}

group = project.mod_group
archivesBaseName = project.mod_name

ext.versionModified = 'git diff-index --quiet HEAD'.execute().waitFor() != 0
ext.versionRevision = 'git rev-list --count HEAD'.execute().text.trim()
ext.versionHash = 'git rev-parse --short HEAD'.execute().text.trim()
version = "0.0.${ext.versionRevision}-${ext.versionHash}${ext.versionModified ? '-MODIFIED' : ''}"

loom {
    accessWidenerPath = file 'src/main/resources/mineseekdestroy.accesswidener'
}

repositories {
    mavenCentral()
    maven {
        name = 'ViaVersion'
        url = uri 'https://repo.viaversion.com/'
    }
    maven {
        name = 'EngineHub'
        url = uri 'https://maven.enginehub.org/repo/'
    }
}

configurations {
    includeImplementation

    implementation {
        extendsFrom includeImplementation
    }
    include {
        extendsFrom includeImplementation
    }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_version}:v2"

    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    includeImplementation "org.jetbrains.kotlin:kotlin-stdlib:${project.kotlin_version}"
    includeImplementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:${project.kotlin_version}"
    includeImplementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8:${project.kotlin_version}"

    modImplementation "com.sk89q.worldedit:worldedit-fabric-mc1.20.4:7.3.0-SNAPSHOT"
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

compileJava {
    options.release = 17
    options.encoding = 'UTF-8'
}

compileKotlin {
    kotlinOptions {
        jvmTarget = '17'
        apiVersion = '1.9'
        languageVersion = '1.9'
        freeCompilerArgs += [
            '-Xno-call-assertions',
            '-Xno-receiver-assertions',
            '-Xno-param-assertions',
        ]
    }
}

processResources {
    filesMatching('fabric.mod.json') {
        expand 'version': version
    }
}