justfile.infra

# Justfile for infra

# This list of actions.
infra:
    @ just -l --unsorted | grep infra

# Sample calls
infra-tldr:
    # Sample of calls:
    @ echo ""
    # $ just infra-help                                 # Just in case you like to read.
    # $ just infra-list                                 # For a detailed list of actions.

    # $ just infra-install-ansible                      # Install ansible in your local machine
    # $ just infra-run info-ps $SERVER -K               # TEST: if you can reach your remote server

    # $ just infra-dist-upgrade $SERVER                 # Upgrades the full system (-K is implicit)
    # $ just infra-run install-basic $SERVER            # Essential tooling (curl, rsync, pip...)
    # $ just infra-run install-docker $SERVER           # Docker and compose are also essential.
    # $ just infra-run info-docker $SERVER              # TEST: docker and docker-compose.

    # $ just infra-run create-user $SERVER              # Create docker user and group and folders.
    @echo ""
    # > To get a commented list of actions use "just infra"


# Shows how to use the script
infra-help:
    # README for infrastructure playbooks
    @ cat {{ infraPath }}/README.md
    @ echo ""


# An alias for "just list infra" that shows a full list of infra's actions
infra-list:
    @ just list infra


# Installs ansible the required roles in your laptop.
infra-install-ansible:
    sudo apt install ansible git
    sudo python3 -m venv venv
    # Activates the virtual environment (in Unix/Linux systems)
    bash -c "source venv/bin/activate"
    ansible-galaxy install -r requirements.yml


# Runs an action (playbook) from /playbooks/infra as root.
infra-run action host *args:
    ansible-playbook -i {{ inventoryPath }}/hosts.yml \
        --limit {{ host }} {{ infraPath }}/{{ action }}.yml -K {{ args }}


# Shows the description of the specified playbook. Run "just infra-list" for a list.
infra-show playbook:
    cat {{ infraPath }}/{{ playbook }}.yml 


# Runs a dist-upgrade, remove unused dependences and reboot.
infra-dist-upgrade host:
    ansible-playbook -i {{ inventoryPath }}/hosts.yml \
        --limit {{ host }} {{ infraPath }}/dist-upgrade.yml -K


# Runs an "apt update" and "apt ugrade" and show the result.
infra-update-upgrade host:
    ansible-playbook -i {{ inventoryPath }}/hosts.yml \
        --limit {{ host }} {{ infraPath }}/update-upgrade.yml -K