build.gradle

allprojects {
    // This can get extracted into a root build.gradle if needed
    ext {
        getLatestTag = {
            new ByteArrayOutputStream().withStream { os ->
                exec {
                    executable = "git"
                    args = ["describe", "--tags", "--abbrev=0"]
                    standardOutput = os
                }
                return os.toString().trim()
            }
        }

        getCurrentCommitCount = {
            new ByteArrayOutputStream().withStream { os ->
                exec {
                    executable = "git"
                    args = ["rev-list", "--all", "--count"]
                    standardOutput = os
                }
                return os.toString().trim()
            }
        }
    }

    try {
        project.version = "${project.ext.getLatestTag()}-${project.ext.getCurrentCommitCount()}"
    } catch (Exception ignored) {
        println('Either git is not set up properly, or there is no tag yet in the repository. Falling back to version \'0\'')
        project.version = '0'
    }
    project.group = 'michiruf'
}