diff --git a/build.gradle b/build.gradle
deleted file mode 100644
index f9d8a33..0000000
--- a/build.gradle
+++ /dev/null
@@ -1,21 +0,0 @@
-buildscript {
-  ext.kotlin_version = '1.9.23'
-  repositories {
-    mavenCentral()
-    gradlePluginPortal()
-  }
-  dependencies {
-    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
-  }
-}
-
-allprojects {
-  repositories {
-    google()
-    mavenCentral()
-  }
-}
-
-task clean(type: Delete) {
-  delete rootProject.buildDir
-}
diff --git a/build.gradle.kts b/build.gradle.kts
new file mode 100644
index 0000000..75cbe4a
--- /dev/null
+++ b/build.gradle.kts
@@ -0,0 +1,45 @@
+import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
+
+plugins {
+  kotlin("jvm") version libs.versions.kotlin.get()
+  alias(libs.plugins.detekt)
+  alias(libs.plugins.ktlint)
+}
+
+kotlin {
+  jvmToolchain(libs.versions.java.get().toInt())
+}
+
+java {
+  sourceCompatibility = JavaVersion.toVersion(libs.versions.java.get())
+  targetCompatibility = JavaVersion.toVersion(libs.versions.java.get())
+
+  toolchain.languageVersion.set(JavaLanguageVersion.of(libs.versions.java.get().toInt()))
+}
+
+subprojects {
+  apply(plugin = rootProject.libs.plugins.ktlint.get().pluginId)
+  apply(plugin = rootProject.libs.plugins.detekt.get().pluginId)
+
+  tasks.withType<KotlinCompile> {
+    kotlinOptions.jvmTarget = libs.versions.java.get()
+  }
+
+  configure<org.jlleitschuh.gradle.ktlint.KtlintExtension> {
+    version.set(rootProject.libs.versions.ktlint.get())
+    verbose.set(true)
+    filter {
+      exclude("**/generated/**", "**/build/**")
+      include("src//kotlin")
+    }
+  }
+
+  detekt {
+    buildUponDefaultConfig = true
+    parallel = true
+  }
+}
+
+// tasks.register("clean", Delete::class) {
+//  delete(rootProject.layout.buildDirectory)
+// }
diff --git a/gradle.properties b/gradle.properties
index a96aa49..7077d0e 100644
--- a/gradle.properties
+++ b/gradle.properties
@@ -3,5 +3,5 @@
 org.gradle.jvmargs=-Xmx2048m -XX:+HeapDumpOnOutOfMemoryError -Dfile.encoding=UTF-8
 org.gradle.parallel=true
 org.gradle.daemon=true
-VERSION_NAME=0.1.0
 
+kotlin.code.style=official
diff --git a/gradle/libs.versions.toml b/gradle/libs.versions.toml
new file mode 100644
index 0000000..42b0924
--- /dev/null
+++ b/gradle/libs.versions.toml
@@ -0,0 +1,22 @@
+[versions]
+detekt = "1.23.5"
+java = "17"
+junit = "4.13.2"
+kotlin = "1.9.23"
+ktlint = "1.1.1"
+ktlintGradle = "12.1.0"
+pluginPublish = "1.2.1"
+
+[libraries]
+kotlin-stdlib = { module = "org.jetbrains.kotlin:kotlin-stdlib", version.ref = "kotlin" }
+junit = { module = "junit:junit", version.ref = "junit" }
+
+
+[plugins]
+detekt = { id = "io.gitlab.arturbosch.detekt", version.ref = "detekt"}
+kotlin = { id = "org.jetbrains.kotlin.jvm", version.ref = "kotlin"}
+ktlint = { id = "org.jlleitschuh.gradle.ktlint", version.ref = "ktlintGradle"}
+pluginPublish = { id = "com.gradle.plugin-publish", version.ref = "pluginPublish"}
+
+
+[bundles]
diff --git a/plugin/build.gradle b/plugin/build.gradle
deleted file mode 100644
index 5afd6dd..0000000
--- a/plugin/build.gradle
+++ /dev/null
@@ -1,46 +0,0 @@
-plugins {
-  id "com.gradle.plugin-publish" version "1.2.1"
-  id "java-gradle-plugin"
-}
-
-apply plugin: 'kotlin'
-
-repositories {
-  mavenCentral()
-}
-
-dependencies {
-  implementation gradleApi()
-  implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
-
-  testImplementation 'junit:junit:4.13.2'
-}
-
-compileKotlin {
-  kotlinOptions {
-    jvmTarget = "17"
-  }
-}
-compileTestKotlin {
-  kotlinOptions {
-    jvmTarget = "17"
-  }
-}
-
-group = 'com.jraska.module.graph.assertion'
-
-gradlePlugin {
-  website = 'https://github.com/jraska/modules-graph-assert'
-  vcsUrl = 'https://github.com/jraska/modules-graph-assert'
-
-  plugins {
-    modulesGraphAssert {
-      id = 'com.jraska.module.graph.assertion'
-      version = '3.0.0'
-      displayName = 'Modules Graph Assert'
-      description = 'Gradle plugin to keep your modules graph healthy and lean.'
-      implementationClass = 'com.jraska.module.graph.assertion.ModuleGraphAssertionsPlugin'
-      tags.addAll('graph', 'assert', 'build speed', 'android', 'java', 'kotlin', 'quality', 'multiprojects', 'module')
-    }
-  }
-}
diff --git a/plugin/build.gradle.kts b/plugin/build.gradle.kts
new file mode 100644
index 0000000..32fff7e
--- /dev/null
+++ b/plugin/build.gradle.kts
@@ -0,0 +1,31 @@
+plugins {
+  alias(libs.plugins.pluginPublish)
+  `java-gradle-plugin`
+}
+
+apply(plugin = "kotlin")
+
+dependencies {
+  implementation(gradleApi())
+  implementation(libs.kotlin.stdlib)
+
+  implementation(libs.junit)
+}
+
+group = "com.jraska.module.graph.assertion"
+
+gradlePlugin {
+  website = "https://github.com/jraska/modules-graph-assert"
+  vcsUrl = "https://github.com/jraska/modules-graph-assert"
+
+  plugins {
+    create("modulesGraphAssert") {
+      id = "com.jraska.module.graph.assertion"
+      version = "3.0.0"
+      displayName = "Modules Graph Assert"
+      description = "Gradle plugin to keep your modules graph healthy and lean."
+      implementationClass = "com.jraska.module.graph.assertion.ModuleGraphAssertionsPlugin"
+      tags.addAll("graph", "assert", "build speed", "android(", ")java", "kotlin", "quality", "multiprojects", "module")
+    }
+  }
+}
diff --git a/settings.gradle b/settings.gradle
deleted file mode 100644
index 3e27ec9..0000000
--- a/settings.gradle
+++ /dev/null
@@ -1 +0,0 @@
-include ':plugin'
\ No newline at end of file
diff --git a/settings.gradle.kts b/settings.gradle.kts
new file mode 100644
index 0000000..6f3d174
--- /dev/null
+++ b/settings.gradle.kts
@@ -0,0 +1,19 @@
+// https://docs.gradle.org/current/userguide/declaring_repositories.html
+pluginManagement {
+  repositories {
+    mavenCentral()
+    gradlePluginPortal()
+  }
+}
+
+dependencyResolutionManagement {
+  repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
+  repositories {
+    google()
+    mavenCentral()
+  }
+}
+
+rootProject.name = "Modules Graph Assert"
+
+include(":plugin")