Retrieve mappings from Bioportal for Biolink cats

[caufieldjh]

We have many nodes assigned biolink:NamedThing category by default, but these could be assigned other categories if a mapping is available, e.g. UMLS semantic types.

See API call: https://data.bioontology.org/mappings?ontologies=SNOMEDCT,BIOLINK
(but there is a bug limiting this for now)

[caufieldjh]

See also https://data.bioontology.org/documentation#Mapping

[caufieldjh]

As per @jvendetti , a SPARQL query for retrieving mappings from one ontology to another would look like:

SELECT DISTINCT ?s1 ?s2  ?source ?o
WHERE {
{
  GRAPH <http://data.bioontology.org/ontologies/MAPPING_TEST1/submissions/11> {
      ?s1 <http://bioportal.bioontology.org/ontologies/umls/cui> ?o .
  }
  GRAPH <http://data.bioontology.org/ontologies/MAPPING_TEST4/submissions/44> {
      ?s2 <http://bioportal.bioontology.org/ontologies/umls/cui> ?o .
  }
  BIND ('CUI' AS ?source)
}

UNION
{
  GRAPH <http://data.bioontology.org/ontologies/MAPPING_TEST1/submissions/11> {
      ?s1 <http://data.bioontology.org/metadata/def/mappingSameURI> ?o .
  }
  GRAPH <http://data.bioontology.org/ontologies/MAPPING_TEST4/submissions/44> {
      ?s2 <http://data.bioontology.org/metadata/def/mappingSameURI> ?o .
  }
  BIND ('SAME_URI' AS ?source)
}

UNION
{
  GRAPH <http://data.bioontology.org/ontologies/MAPPING_TEST1/submissions/11> {
      ?s1 <http://data.bioontology.org/metadata/def/mappingLoom> ?o .
  }
  GRAPH <http://data.bioontology.org/ontologies/MAPPING_TEST4/submissions/44> {
      ?s2 <http://data.bioontology.org/metadata/def/mappingLoom> ?o .
  }
  BIND ('LOOM' AS ?source)
}

UNION
{
  GRAPH <http://data.bioontology.org/ontologies/MAPPING_TEST1/submissions/11> {
      ?s1 <http://data.bioontology.org/metadata/def/mappingRest> ?o .
  }
  GRAPH <http://data.bioontology.org/ontologies/MAPPING_TEST4/submissions/44> {
      ?s2 <http://data.bioontology.org/metadata/def/mappingRest> ?o .
  }
  BIND ('REST' AS ?source)
}

FILTER ((?s1 != ?s2) || (?source = 'SAME_URI'))
} OFFSET 0 LIMIT 5

where ontology IDs and submission IDs are MAPPING_TEST1, 11 and MAPPING_TEST4, 44, respectively.
See also https://github.com/ncbo/ontologies_linked_data/blob/fc90752c9476cdbd06b102577aec2f9110fbce8d/test/models/test_mappings.rb#L175