forked from lhcopt/hllhc13
-
Notifications
You must be signed in to change notification settings - Fork 0
/
hllhc_sequence.madx
1597 lines (1342 loc) · 56 KB
/
hllhc_sequence.madx
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
! S. Fartoukh: 06/06/2009: Version compatible with beam1, beam2 or beam4;
! Revised version for SLHCV2: S. Fartoukh 30.09.2009
! Based on SLHCV3.0/removeinstall.madx
! 2011/11 R. De Maria
! To be called once at the beginning of the script
! Use removeinstall.madx to place and displace elements
! - New name conventions and element classes
! - Additional orbit correctors for closed crossing scheme
! - Movable D2,Q4,Q5,Q6
! - MQYL in Q5 IR6
! - Addition MS in Q10
! - Default reference radius
! - Additional corrector package
! 2012/03/19 new MCBX lengths and position, new BPMS position
! bug in a5/b5 kmax corrected
! 2012/03/20 new name for BPM in the triplet from BPMSD to BPMSQ
! xywab(d)e already taken
! 2012/03/20 a5/b5 bug in the definition of the strengths
! 2012/07/13 Crab cavity elements as tkickers
! 2016/08/23 Updated layout after rebaselining
!-------------------------------------------------------------------
! Remove install old and new elements
! Triplets, interconnection lenghts and MS postions are defined
! by the calling program
! -----------------------------------------------------------
! mylhcbeam=4 for Beam 4
if (mylhcbeam>2){ bv_aux=-1; } else { bv_aux=1; };
if (on_layout_custom==0){
l.MQXFA = 4.2000000000 ;
l.MQXFB = 7.1500000000 ;
dq1q2a = 3.6280000000 ;
dq1aq1b = 0.6060000000 ; !-0.04 from V1.2
dq2aq2b = 2.1080000000 ;
dq2bq3 = 3.6280000000 ;
deltaposD2 = -15.3870000000 ;!max. field D2 35 Tm -> move D2 as close as possible to D1
deltaposQ4 = 10.047 ;
deltaposQ5 = 11.0000000000 ;
deltaposQ6 = 0.0000000000 ;
on_cutMS.10f = 0 ;
on_cutMS.14f = 0 ;
on_cutMS.10d = 0 ;
on_cutMS.14d = 0 ;
l.MBXF = 6.27 ;
l.MCBXFB = 1.2 ;
l.MCBXFA = 2.2 ;
l.MBRD = 7.78 ;
l.MCBRD = 1.89 ;
};
!value, l.MQXL,l.MQX,dq1q2a,dq2aq2b,dq2bq3;
!value, deltaposD2;
!value, deltaposQ4;
!value, deltaposQ5;
!value, deltaposQ6;
!===============================================
! REMOVE CURRENT INSERTION (from TAS to Q6)
!===============================================
if(bv_aux ==1){
seqedit,sequence=lhcb1;flatten;endedit;
};
seqedit,sequence=lhcb2;flatten;endedit;
brho = 23348.89927;
removemarker: marker;
marks.l1: removemarker; marke.l1: removemarker;
marks.l5: removemarker; marke.l5: removemarker;
marks.r1: removemarker; marke.r1: removemarker;
marks.r5: removemarker; marke.r5: removemarker;
posmarke=15.0;
!posmarks=163.0; ! include D2
!posmarks=184; ! include Q4
!posmarks=240; ! include Q6
posmarks=259; ! include Q6 DFBAJ DFBAI
if(bv_aux == 1){
seqedit, sequence=lhcb1;
install,element=marks.l1,class=removemarker,at=-posmarks,from=IP1.L1;
install,element=marke.l1,class=removemarker,at=-posmarke,from=IP1.L1;
install,element=marke.r1,class=removemarker,at= posmarke,from=IP1;
install,element=marks.r1,class=removemarker,at= posmarks,from=IP1;
install,element=marks.l5,class=removemarker,at=-posmarks,from=IP5;
install,element=marke.l5,class=removemarker,at=-posmarke,from=IP5;
install,element=marke.r5,class=removemarker,at= posmarke,from=IP5;
install,element=marks.r5,class=removemarker,at= posmarks,from=IP5;
endedit;
seqedit, sequence=lhcb1;
select, flag=seqedit, clear;
select, flag=seqedit, range=marks.l1/marke.l1;
select, flag=seqedit, range=marke.r1/marks.r1;
select, flag=seqedit, range=marks.l5/marke.l5;
select, flag=seqedit, range=marke.r5/marks.r5;
remove, element=selected;
endedit;
seqedit, sequence=lhcb1;
select, flag=seqedit, clear;
select, flag=seqedit, class=BRANA;
select, flag=seqedit, class=X1FCL;
select, flag=seqedit, class=X1FCR;
select, flag=seqedit, class=X1ZDC001;
select, flag=seqedit, class=X5ZDC001;
select, flag=seqedit, class=X5ZDC002;
remove, element=selected;
endedit;
seqedit,sequence=lhcb1;
remove, element=MCBCH.10L1.B1;
remove, element=MCBCV.10R1.B1;
remove, element=MCBCH.10L5.B1;
remove, element=MCBCV.10R5.B1;
remove, element=MS.10L1.B1;
remove, element=MS.10R1.B1;
remove, element=MS.10L5.B1;
remove, element=MS.10R5.B1;
remove, element=MCBH.10L1.B1;
remove, element=MCBV.10R1.B1;
remove, element=MCBH.10L5.B1;
remove, element=MCBV.10R5.B1;
endedit;
! seqedit,sequence=lhcb1;
! remove,element=MQY.5L6.B1;
! remove,element=MQY.5R6.B1;
! remove,element=BPMYA.5L6.B1;
! remove,element=MQYL.5L6.B1 ;
! remove,element=MQYL.5R6.B1 ;
! remove,element=MCBYV.5R6.B1;
! endedit;
};
seqedit, sequence=lhcb2;
install,element=marks.l1,class=removemarker,at=-posmarks*bv_aux,from=IP1.L1;
install,element=marke.l1,class=removemarker,at=-posmarke*bv_aux,from=IP1.L1;
install,element=marke.r1,class=removemarker,at= posmarke*bv_aux,from=IP1;
install,element=marks.r1,class=removemarker,at= posmarks*bv_aux,from=IP1;
install,element=marks.l5,class=removemarker,at=-posmarks*bv_aux,from=IP5;
install,element=marke.l5,class=removemarker,at=-posmarke*bv_aux,from=IP5;
install,element=marke.r5,class=removemarker,at= posmarke*bv_aux,from=IP5;
install,element=marks.r5,class=removemarker,at= posmarks*bv_aux,from=IP5;
endedit;
if(bv_aux == 1){
seqedit, sequence=lhcb2;
select, flag=seqedit, clear;
select, flag=seqedit, range=marks.l1/marke.l1;
select, flag=seqedit, range=marke.r1/marks.r1;
select, flag=seqedit, range=marks.l5/marke.l5;
select, flag=seqedit, range=marke.r5/marks.r5;
remove, element=selected;
endedit;
} else {
seqedit, sequence=lhcb2;
select, flag=seqedit, clear;
select, flag=seqedit, range=marke.l1/marks.l1;
select, flag=seqedit, range=marks.r1/marke.r1;
select, flag=seqedit, range=marke.l5/marks.l5;
select, flag=seqedit, range=marks.r5/marke.r5;
remove, element=selected;
endedit;
};
seqedit, sequence=lhcb2;
select, flag=seqedit, clear;
select, flag=seqedit, class=BRANA;
select, flag=seqedit, class=X1FCL;
select, flag=seqedit, class=X1FCR;
select, flag=seqedit, class=X1ZDC001;
select, flag=seqedit, class=X5ZDC001;
select, flag=seqedit, class=X5ZDC002;
remove, element=selected;
endedit;
! remove old Q10 corrector package
seqedit,sequence=lhcb2;
remove, element=MCBCV.10L1.B2;
remove, element=MCBCH.10R1.B2;
remove, element=MCBCV.10L5.B2;
remove, element=MCBCH.10R5.B2;
remove, element=MS.10L1.B2;
remove, element=MS.10R1.B2;
remove, element=MS.10L5.B2;
remove, element=MS.10R5.B2;
remove, element=MCBV.10L1.B2;
remove, element=MCBH.10R1.B2;
remove, element=MCBV.10L5.B2;
remove, element=MCBH.10R5.B2;
endedit;
! remove old Q5 in IR6
!seqedit,sequence=lhcb2;
!remove,element=MQY.5L6.B2;
!remove,element=MQY.5R6.B2;
!remove,element=BPMYB.5L6.B2;
!remove,element=MQYL.5L6.B2 ;
!remove,element=MQYL.5R6.B2 ;
!remove,element=MCBYH.5R6.B2;
!endedit;
! ===============================================
! macros for installation
! ===============================================
install_ir15_cmn(ENAME,SPOS): macro={
value,SPOS;
if(bv_aux == 1){
seqedit,sequence=lhcb1;
install, element=ENAMEL1,at=-SPOS,from=IP1.L1;
install, element=ENAMER1,at= SPOS,from=IP1;
install, element=ENAMEL5,at=-SPOS,from=IP5;
install, element=ENAMER5,at= SPOS,from=IP5;
endedit;
};
seqedit,sequence=lhcb2;
install, element=ENAMEL1,at=-SPOS *bv_aux,from=IP1.L1;
install, element=ENAMER1,at= SPOS *bv_aux,from=IP1;
install, element=ENAMEL5,at=-SPOS *bv_aux,from=IP5;
install, element=ENAMER5,at= SPOS *bv_aux,from=IP5;
endedit;
};
install_ir15_b12(ENAME,SPOS): macro={
value,SPOS;
if(bv_aux == 1){
seqedit,sequence=lhcb1;
install, element=ENAMEL1.B1,at=-SPOS,from=IP1.L1;
install, element=ENAMER1.B1,at= SPOS,from=IP1;
install, element=ENAMEL5.B1,at=-SPOS,from=IP5;
install, element=ENAMER5.B1,at= SPOS,from=IP5;
endedit;
};
seqedit,sequence=lhcb2;
install, element=ENAMEL1.B2,at=-SPOS*bv_aux,from=IP1.L1;
install, element=ENAMER1.B2,at= SPOS*bv_aux,from=IP1;
install, element=ENAMEL5.B2,at=-SPOS*bv_aux,from=IP5;
install, element=ENAMER5.B2,at= SPOS*bv_aux,from=IP5;
endedit;
};
install_ir15_b1_b2(ENAME,SPOS1,SPOS2): macro={
! orientation:b1 spos1 - IP - spos1
! orientation:b2 spos2 - IP - spos2
! -> orientation:
! b1: h v - IP - v h
! b2: v h - IP - h v
value,SPOS1,SPOS2;
if(bv_aux == 1){
seqedit,sequence=lhcb1;
install, element=ENAMEL1.B1,at=-SPOS1,from=IP1.L1;
install, element=ENAMER1.B1,at= SPOS1,from=IP1;
install, element=ENAMEL5.B1,at=-SPOS1,from=IP5;
install, element=ENAMER5.B1,at= SPOS1,from=IP5;
endedit;
};
seqedit,sequence=lhcb2;
install, element=ENAMEL1.B2,at=-SPOS2*bv_aux,from=IP1.L1;
install, element=ENAMER1.B2,at= SPOS2*bv_aux,from=IP1;
install, element=ENAMEL5.B2,at=-SPOS2*bv_aux,from=IP5;
install, element=ENAMER5.B2,at= SPOS2*bv_aux,from=IP5;
endedit;
};
install_ir15_b1_b2_inv(ENAME,SPOS1,SPOS2): macro={
value,SPOS1,SPOS2;
if(bv_aux == 1){
seqedit,sequence=lhcb1;
install, element=ENAMEL1.B1,at=-SPOS2,from=IP1.L1;
install, element=ENAMER1.B1,at= SPOS1,from=IP1;
install, element=ENAMEL5.B1,at=-SPOS1,from=IP5;
install, element=ENAMER5.B1,at= SPOS2,from=IP5;
endedit;
};
seqedit,sequence=lhcb2;
install, element=ENAMEL1.B2,at=-SPOS2*bv_aux,from=IP1.L1;
install, element=ENAMER1.B2,at= SPOS1*bv_aux,from=IP1;
install, element=ENAMEL5.B2,at=-SPOS1*bv_aux,from=IP5;
install, element=ENAMER5.B2,at= SPOS2*bv_aux,from=IP5;
endedit;
};
install_ir15_b1_b2_alt(ENAME,SPOS1,SPOS2): macro={
! orientation:b1 spos1 - IP - spos2
! orientation:b2 spos2 - IP - spos1
! -> orientation:
! b1: h v - IP - h v
! b2: v h - IP - v h
value,SPOS1,SPOS2;
if(bv_aux == 1){
seqedit,sequence=lhcb1;
install, element=ENAMEL1.B1,at=-SPOS1,from=IP1.L1;
install, element=ENAMER1.B1,at= SPOS2,from=IP1;
install, element=ENAMEL5.B1,at=-SPOS1,from=IP5;
install, element=ENAMER5.B1,at= SPOS2,from=IP5;
endedit;
};
seqedit,sequence=lhcb2;
install, element=ENAMEL1.B2,at=-SPOS2*bv_aux,from=IP1.L1;
install, element=ENAMER1.B2,at= SPOS1*bv_aux,from=IP1;
install, element=ENAMEL5.B2,at=-SPOS2*bv_aux,from=IP5;
install, element=ENAMER5.B2,at= SPOS1*bv_aux,from=IP5;
endedit;
};
newel_ir15_b12(ENAME,PARE): macro={
ENAMEL1.B1: PARE; ENAMEL1.B2: PARE;
ENAMER1.B1: PARE; ENAMER1.B2: PARE;
ENAMEL5.B1: PARE; ENAMEL5.B2: PARE;
ENAMER5.B1: PARE; ENAMER5.B2: PARE;
};
!===============================================
! TAS
!===============================================
posTAS =19.950;
l.TAXS =1.8;
TAXS: RCOLLIMATOR, L := l.TAXS; ! new TAS
TAXS.1R1: TAXS; TAXS.1L1: TAXS;
TAXS.1R5: TAXS; TAXS.1L5: TAXS;
! TAS
exec,install_ir15_cmn(TAXS.1, posTAS );
!===============================================
! Triplet region
!===============================================
! Lstar {.46 |Q1|}
Lstar =23.00-0.08; !22.965 m in V6.503
posQ1a:=Lstar +l.MQXFA/2.;
posQ1b:=posQ1a+l.MQXFA+dq1aq1b;
posQ2a:=posQ1b+(l.MQXFA+l.MQXFB)/2.+dq1q2a;
posQ2b:=posQ2a+l.MQXFB+dq2aq2b;
posQ3a:=posQ2b+(l.MQXFA+l.MQXFB)/2.+dq2bq3;
posQ3b:=posQ3a+l.MQXFA+dq1aq1b;
value, posQ1a,posQ1b,posQ2a,posQ2b,posQ3a,posQ3b;
Kmax_MQXFA=132.6;
Kmax_MQXFB=132.6;
Kmin_MQXFA=132.6*0.03;
Kmin_MQXFB=132.6*0.03;
Imax_MQXFA=16470;
Imax_MQXFB=16470;
! new element types
MQXFA: QUADRUPOLE, L := l.MQXFA, ! Q1 Q3
Kmax:= Kmax_MQXFA, Kmin:= Kmax_MQXFA, Calib=Kmax_MQXFA/Imax_MQXFA;
MQXFB: QUADRUPOLE, L := l.MQXFB, ! Q2a Q2b
Kmax:= Kmax_MQXFB, Kmin:= Kmax_MQXFB, Calib=Kmax_MQXFB/Imax_MQXFB;
! triplet quad strengths in IR1 & IR5
MQXFA.A1L1 : MQXFA,k1:= kqx1.l1 *bv_aux;
MQXFA.A1R1 : MQXFA,k1:= kqx1.r1 *bv_aux;
MQXFA.B1L1 : MQXFA,k1:= kqx1.l1 *bv_aux;
MQXFA.B1R1 : MQXFA,k1:= kqx1.r1 *bv_aux;
MQXFB.A2L1 : MQXFB,k1:=-kqx2a.l1 *bv_aux;
MQXFB.B2L1 : MQXFB,k1:=-kqx2b.l1 *bv_aux;
MQXFB.A2R1 : MQXFB,k1:=-kqx2a.r1 *bv_aux;
MQXFB.B2R1 : MQXFB,k1:=-kqx2b.r1 *bv_aux;
MQXFA.A3L1 : MQXFA,k1:= kqx3.l1 *bv_aux;
MQXFA.A3R1 : MQXFA,k1:= kqx3.r1 *bv_aux;
MQXFA.B3L1 : MQXFA,k1:= kqx3.l1 *bv_aux;
MQXFA.B3R1 : MQXFA,k1:= kqx3.r1 *bv_aux;
MQXFA.A1L5 : MQXFA,k1:= kqx1.l5 *bv_aux;
MQXFA.A1R5 : MQXFA,k1:= kqx1.r5 *bv_aux;
MQXFA.B1L5 : MQXFA,k1:= kqx1.l5 *bv_aux;
MQXFA.B1R5 : MQXFA,k1:= kqx1.r5 *bv_aux;
MQXFB.A2L5 : MQXFB,k1:=-kqx2a.l5 *bv_aux;
MQXFB.B2L5 : MQXFB,k1:=-kqx2b.l5 *bv_aux;
MQXFB.A2R5 : MQXFB,k1:=-kqx2a.r5 *bv_aux;
MQXFB.B2R5 : MQXFB,k1:=-kqx2b.r5 *bv_aux;
MQXFA.A3L5 : MQXFA,k1:= kqx3.l5 *bv_aux;
MQXFA.A3R5 : MQXFA,k1:= kqx3.r5 *bv_aux;
MQXFA.B3L5 : MQXFA,k1:= kqx3.l5 *bv_aux;
MQXFA.B3R5 : MQXFA,k1:= kqx3.r5 *bv_aux;
! Triplet
exec,install_ir15_cmn(MQXFA.A1, posQ1a );
exec,install_ir15_cmn(MQXFA.B1, posQ1b );
exec,install_ir15_cmn(MQXFB.A2, posQ2A );
exec,install_ir15_cmn(MQXFB.B2, posQ2B );
exec,install_ir15_cmn(MQXFA.A3, posQ3a );
exec,install_ir15_cmn(MQXFA.B3, posQ3b );
!===============================================
! MCBX in Q2 (small orbit corrector)
!===============================================
! .488 should become 478 and 479 to be checked...
! MCBX
! Q1 |.5 } 1 {.5 | MCBXFBa | .488 | Q2a
! Q2a |.5 } 1 {.5 | Q2b | .489| MCBXFBb |.5 }
! Q2b |.489 | MCBXFBb |.1 } .1 {.5 | Q3 | .5}
posMCBXFBa := posQ2a -(l.MQXFB + l.MCBXFB )/2. -0.488;
posMCBXFBb := posQ2b +(l.MQXFB + l.MCBXFB )/2. +0.488;
!value,l.MCBXFB, posMCBXFBa,posMCBXFBb;
! Cabling orbit corrector inside Q2a and Q2b cold masses
MCBXFBH: HKICKER, Lrad := l.MCBXFB; ! nested corrector
MCBXFBV: VKICKER, Lrad := l.MCBXFB; ! nested corrector
Kmax_MCBXFB := 2.5000 / l.MCBXFB; ! 1.8Tm integrated strength
Kmin_MCBXFB := -Kmax_MCBXFB ;
value, Kmax_MCBXFB;
MCBXFBH, Kmax:=Kmax_MCBXFB, Kmin:=Kmin_MCBXFB;
MCBXFBV, Kmax:=Kmax_MCBXFB, Kmin:=Kmin_MCBXFB;
MCBXFBH.a2L1: MCBXFBH, KICK := acbxh1.l1;
MCBXFBH.a2R1: MCBXFBH, KICK := acbxh1.r1;
MCBXFBH.a2L5: MCBXFBH, KICK := acbxh1.l5;
MCBXFBH.a2R5: MCBXFBH, KICK := acbxh1.r5;
MCBXFBV.a2L1: MCBXFBV, KICK := acbxv1.l1*bv_aux;
MCBXFBV.a2R1: MCBXFBV, KICK := acbxv1.r1*bv_aux;
MCBXFBV.a2L5: MCBXFBV, KICK := acbxv1.l5*bv_aux;
MCBXFBV.a2R5: MCBXFBV, KICK := acbxv1.r5*bv_aux;
MCBXFBH.b2L1: MCBXFBH, KICK := acbxh2.l1;
MCBXFBH.b2R1: MCBXFBH, KICK := acbxh2.r1;
MCBXFBH.b2L5: MCBXFBH, KICK := acbxh2.l5;
MCBXFBH.b2R5: MCBXFBH, KICK := acbxh2.r5;
MCBXFBV.b2L1: MCBXFBV, KICK := acbxv2.l1*bv_aux;
MCBXFBV.b2R1: MCBXFBV, KICK := acbxv2.r1*bv_aux;
MCBXFBV.b2L5: MCBXFBV, KICK := acbxv2.l5*bv_aux;
MCBXFBV.b2R5: MCBXFBV, KICK := acbxv2.r5*bv_aux;
! Orbit correctors
exec,install_ir15_cmn(MCBXFBH.A2, posMCBXFBa );
exec,install_ir15_cmn(MCBXFBV.A2, posMCBXFBa );
exec,install_ir15_cmn(MCBXFBH.B2, posMCBXFBb );
exec,install_ir15_cmn(MCBXFBV.B2, posMCBXFBb );
!===============================================
!Corrector package
!===============================================
! layout
l.MQSXF = 0.807 ; !0.716 a2 corrector
l.MCTXF = 0.430 ; !0.339 b6 corrector
l.MCTSXF = 0.089 ; !0.087 a6 corrector
l.MCDXF = 0.095 ; !0.079 b5 corrector
l.MCDSXF = 0.095 ; !0.079 a5 corrector
l.MCOXF = 0.087 ; !0.137 b4 corrector
l.MCOSXF = 0.087 ; !0.137 a4 corrector
l.MCSXF = 0.111 ; !0.121 b3 corrector
l.MCSSXF = 0.111 ; !0.121 a3 corrector
! Q3|.5} 1.00 {.5 | MCBXFA | .5
! .08 | MQSXF | .08
! .08 | MCTXF | .08
! .08 | MCTSXF | .08
! .08 | MCDXF | .08
! .08 | MCDSXF | .08
! .08 | MCOXF | .08
! .08 | MCOSXF | .08
! .08 | MCSXF | .08
! .08 | MCSSXF | .08 }
posMCBXFA := posQ3b + (l.MQXFA + l.MCBXFA )/2.+2.747;
posMQSXF := posMCBXFA + 1.806;
posMCTXF := posMQSXF + 0.772;
posMCTSXF := posMCTXF + 0.410;
posMCDXF := posMCTSXF + 0.239;
posMCDSXF := posMCDXF + 0.242;
posMCOXF := posMCDSXF + 0.242;
posMCOSXF := posMCOXF + 0.242;
posMCSXF := posMCOSXF + 0.248;
posMCSSXF := posMCSXF + 0.254;
value,posMCBXFA,posMQSXF,posMCTXF,posMCTSXF,posMCDXF,posMCDSXF,posMCOXF,posMCOSXF,posMCSXF,posMCSSXF;
! orbit corrector elements
MCBXFAH : HKICKER , Lrad := l.MCBXFA ; ! H in corrector package (long for crabs)
MCBXFAV : VKICKER , Lrad := l.MCBXFA ; ! V in corrector package (long for crabs)
MQSXF : QUADRUPOLE, L := l.MQSXF ; ! (a2)
MCTXF : MULTIPOLE , Lrad := l.MCTXF ; ! (b6)
MCTSXF : MULTIPOLE , Lrad := l.MCTSXF ; ! (a6)
MCDXF : MULTIPOLE , Lrad := l.MCDXF ; ! (b5)
MCDSXF : MULTIPOLE , Lrad := l.MCDSXF ; ! (a5)
MCOXF : MULTIPOLE , Lrad := l.MCOXF ; ! (b4)
MCOSXF : MULTIPOLE , Lrad := l.MCOSXF ; ! (a4)
MCSXF : MULTIPOLE , Lrad := l.MCSXF ; ! (b3)
MCSSXF : MULTIPOLE , Lrad := l.MCSSXF ; ! (a3)
Kmax_MCBXFA:= 4.5000 / l.MCBXFA ;!4.5000Tm@50mm
Rref_mpcorr = 0.05; !50mm reference radius for multipole correctors
Kmax_MQSXF := 1.0000 / l.MQSXF/Rref_mpcorr ;!1.0000Tm@50mm
Kmax_MCTXF := 0.0860 / l.MCTXF /Rref_mpcorr^5 * 120.;!0.0860Tm@50mm
Kmax_MCTSXF:= 0.0170 / l.MCTSXF/Rref_mpcorr^5 * 120.;!0.0170Tm@50mm
Kmax_MCDXF := 0.0250 / l.MCDXF /Rref_mpcorr^4 * 24.;!0.0250Tm@50mm
Kmax_MCDSXF:= 0.0250 / l.MCDSXF/Rref_mpcorr^4 * 24.;!0.0250Tm@50mm
Kmax_MCOXF := 0.0460 / l.MCOXF /Rref_mpcorr^3 * 6.;!0.0460Tm@50mm
Kmax_MCOSXF:= 0.0460 / l.MCOSXF/Rref_mpcorr^3 * 6.;!0.0460Tm@50mm
Kmax_MCSXF := 0.0630 / l.MCSXF /Rref_mpcorr^2 * 2.;!0.0630Tm@50mm
Kmax_MCSSXF:= 0.0630 / l.MCSSXF/Rref_mpcorr^2 * 2.;!0.0630Tm@50mm
Kmin_MCBXFA:= -Kmax_MCBXFA ;
Kmin_MQSXF := -Kmax_MQSXF ;
Kmin_MCSXF := -Kmax_MCSXF ;
Kmin_MCSSXF:= -Kmax_MCSSXF;
Kmin_MCOXF := -Kmax_MCOXF ;
Kmin_MCOSXF:= -Kmax_MCOSXF;
Kmin_MCTXF := -Kmax_MCTXF ;
Kmin_MCDXF := -Kmax_MCDXF ;
Kmin_MCDSXF:= -Kmax_MCDSXF;
Kmin_MCTSXF:= -Kmax_MCTSXF;
Imax_MCTXF = 167;
Imax_MCBXFA=2500;
Imax_MCBXFB=2500;
Imax_MQSXF = 182;
Imax_MCDSXF= 139;
Imax_MCDXF = 139;
Imax_MCOSXF= 132;
Imax_MCOXF = 132;
Imax_MCSSXF= 132;
Imax_MCSXF = 132;
! cabling
MCBXFAH, Kmax:=Kmax_MCBXFA, Kmin:=Kmin_MCBXFA;
MCBXFAV, Kmax:=Kmax_MCBXFA, Kmin:=Kmin_MCBXFA;
MCBXFAH.3L1: MCBXFAH, KICK := acbxh3.l1;
MCBXFAH.3R1: MCBXFAH, KICK := acbxh3.r1;
MCBXFAH.3L5: MCBXFAH, KICK := acbxh3.l5;
MCBXFAH.3R5: MCBXFAH, KICK := acbxh3.r5;
MCBXFAV.3L1: MCBXFAV, KICK := acbxv3.l1*bv_aux;
MCBXFAV.3R1: MCBXFAV, KICK := acbxv3.r1*bv_aux;
MCBXFAV.3L5: MCBXFAV, KICK := acbxv3.l5*bv_aux;
MCBXFAV.3R5: MCBXFAV, KICK := acbxv3.r5*bv_aux;
!A2 CORRECTOR
MQSXF, Kmax:=Kmax_MQSXF , Kmin:=Kmin_MQSXF;
MQSXF.3L1: MQSXF, K1S:=kqsx3.l1;
MQSXF.3R1: MQSXF, K1S:=kqsx3.r1;
MQSXF.3L5: MQSXF, K1S:=kqsx3.l5;
MQSXF.3R5: MQSXF, K1S:=kqsx3.r5;
!B3 CORRECTOR
MCSXF, Kmax:=Kmax_MCSXF , Kmin:=Kmin_MCSXF;
MCSXF.3L1: MCSXF, KNL := {0, 0, kcsx3.l1*l.MCSXF};
MCSXF.3R1: MCSXF, KNL := {0, 0, kcsx3.r1*l.MCSXF};
MCSXF.3L5: MCSXF, KNL := {0, 0, kcsx3.l5*l.MCSXF};
MCSXF.3R5: MCSXF, KNL := {0, 0, kcsx3.r5*l.MCSXF};
!B6 CORRECTOR
MCTXF, Kmax:=Kmax_MCTXF , Kmin:=Kmin_MCTXF;
MCTXF.3L1: MCTXF, KNL := {0, 0, 0, 0, 0, kctx3.l1 *bv_aux*l.MCTXF};
MCTXF.3R1: MCTXF, KNL := {0, 0, 0, 0, 0, kctx3.r1 *bv_aux*l.MCTXF};
MCTXF.3L5: MCTXF, KNL := {0, 0, 0, 0, 0, kctx3.l5 *bv_aux*l.MCTXF};
MCTXF.3R5: MCTXF, KNL := {0, 0, 0, 0, 0, kctx3.r5 *bv_aux*l.MCTXF};
!A6 CORRECTOR
MCTSXF, Kmax:=Kmax_MCTSXF , Kmin:=Kmin_MCTSXF;
MCTSXF.3L1: MCTSXF, KSL := {0, 0, 0, 0, 0, kctsx3.l1 *l.MCTSXF};
MCTSXF.3R1: MCTSXF, KSL := {0, 0, 0, 0, 0, kctsx3.r1 *l.MCTSXF};
MCTSXF.3L5: MCTSXF, KSL := {0, 0, 0, 0, 0, kctsx3.l5 *l.MCTSXF};
MCTSXF.3R5: MCTSXF, KSL := {0, 0, 0, 0, 0, kctsx3.r5 *l.MCTSXF};
!A3 CORRECTOR
MCSSXF, Kmax:=Kmax_MCSSXF, Kmin:=Kmin_MCSSXF;
MCSSXF.3L1: MCSSXF, KSL := {0, 0, kcssx3.l1 *bv_aux*l.MCSSXF};
MCSSXF.3R1: MCSSXF, KSL := {0, 0, kcssx3.r1 *bv_aux*l.MCSSXF};
MCSSXF.3L5: MCSSXF, KSL := {0, 0, kcssx3.l5 *bv_aux*l.MCSSXF};
MCSSXF.3R5: MCSSXF, KSL := {0, 0, kcssx3.r5 *bv_aux*l.MCSSXF};
!A4 CORRECTOR
MCOSXF, Kmax:=Kmax_MCOSXF, Kmin:=Kmin_MCOSXF;
MCOSXF.3L1: MCOSXF, KSL := {0, 0, 0, kcosx3.l1*l.MCOSXF};
MCOSXF.3R1: MCOSXF, KSL := {0, 0, 0, kcosx3.r1*l.MCOSXF};
MCOSXF.3L5: MCOSXF, KSL := {0, 0, 0, kcosx3.l5*l.MCOSXF};
MCOSXF.3R5: MCOSXF, KSL := {0, 0, 0, kcosx3.r5*l.MCOSXF};
!B4 CORRECTOR
MCOXF, Kmax:=Kmax_MCOXF , Kmin:=Kmin_MCOXF;
MCOXF.3L1: MCOXF, KNL := {0, 0, 0, kcox3.l1 *bv_aux*l.MCOXF};
MCOXF.3R1: MCOXF, KNL := {0, 0, 0, kcox3.r1 *bv_aux*l.MCOXF};
MCOXF.3L5: MCOXF, KNL := {0, 0, 0, kcox3.l5 *bv_aux*l.MCOXF};
MCOXF.3R5: MCOXF, KNL := {0, 0, 0, kcox3.r5 *bv_aux*l.MCOXF};
!A5 CORRECTOR
MCDSXF, Kmax:=Kmax_MCDSXF, Kmin:=Kmin_MCDSXF;
MCDSXF.3L1: MCDSXF, KSL := {0, 0, 0, 0, kcdsX3.l1 *bv_aux*l.MCDSXF};
MCDSXF.3R1: MCDSXF, KSL := {0, 0, 0, 0, kcdsX3.r1 *bv_aux*l.MCDSXF};
MCDSXF.3L5: MCDSXF, KSL := {0, 0, 0, 0, kcdsX3.l5 *bv_aux*l.MCDSXF};
MCDSXF.3R5: MCDSXF, KSL := {0, 0, 0, 0, kcdsX3.r5 *bv_aux*l.MCDSXF};
!B5 CORRECTOR
MCDXF, Kmax:=Kmax_MCDXF , Kmin:=Kmin_MCDXF;
MCDXF.3L1: MCDXF, KNL := {0, 0, 0, 0, kcdx3.l1*l.MCDXF};
MCDXF.3R1: MCDXF, KNL := {0, 0, 0, 0, kcdx3.r1*l.MCDXF};
MCDXF.3L5: MCDXF, KNL := {0, 0, 0, 0, kcdx3.l5*l.MCDXF};
MCDXF.3R5: MCDXF, KNL := {0, 0, 0, 0, kcdx3.r5*l.MCDXF};
! Installl non linear correctors
exec,install_ir15_cmn(MCBXFAH.3,posMCBXFA); !b1
exec,install_ir15_cmn(MCBXFAV.3,posMCBXFA); !a1
exec,install_ir15_cmn(MQSXF.3, posMQSXF); !a2
exec,install_ir15_cmn(MCTXF.3, posMCTXF ); !b6
exec,install_ir15_cmn(MCTSXF.3, posMCTSXF ); !a6
exec,install_ir15_cmn(MCDXF.3, posMCDXF ); !b5
exec,install_ir15_cmn(MCDSXF.3, posMCDSXF ); !a5
exec,install_ir15_cmn(MCOXF.3, posMCOXF ); !b4
exec,install_ir15_cmn(MCOSXF.3, posMCOSXF ); !a4
exec,install_ir15_cmn(MCSXF.3, posMCSXF ); !b3
exec,install_ir15_cmn(MCSSXF.3, posMCSSXF ); !a3
!===============================================
! D1 area
!===============================================
! separation recombination dipoles
!if (l.MBXF==0) {l.MBXF= 6.27;};
!l.MBXF= 6.69;
!l.MBXF= 6.36;
!l.MBXF= 6.27;
MBXF : RBEND, L := l.MBXF ; ! D1
!BPMWC: MONITOR, L := l.BPMWC; ! bpm in D1
! service module for current distribution in the non-IP side of D1
l.DFXJ = 3.658; ! not finalized
DFXJ : PLACEHOLDER, L:= l.DFXJ;
! Layout
! MCSSXF | .5} .1 {.5 D1 .5} 1 DFXJ
!posD1 := posMCSSXF+(l.MBXF+l.MCSSXF)/2.+2;
posD1 = posQ3b+(l.MQXFA+l.MBXF)/2+1.047+7.954+1.050;
posDFXJ := 82.127+l.DFXJ/2;
!posBPMWC := posD1 + l.MBXF/2 + 0.90; ! to be checked with long range
! Separation recombination dipoles
MBXF.4L1: MBXF,angle:= ad1.lr1, K0 := kd1.lr1, polarity=+1 *bv_aux;
MBXF.4R1: MBXF,angle:=-ad1.lr1, K0 :=-kd1.lr1, polarity=-1 *bv_aux;
MBXF.4L5: MBXF,angle:= ad1.lr5, K0 := kd1.lr5, polarity=+1 *bv_aux;
MBXF.4R5: MBXF,angle:=-ad1.lr5, K0 :=-kd1.lr5, polarity=-1 *bv_aux;
!BPMWC.4L1.B1: BPMWC;
!BPMWC.4R1.B1: BPMWC;
!BPMWC.4L5.B1: BPMWC;
!BPMWC.4R5.B1: BPMWC;
!BPMWC.4L1.B2: BPMWC;
!BPMWC.4R1.B2: BPMWC;
!BPMWC.4L5.B2: BPMWC;
!BPMWC.4R5.B2: BPMWC;
DFXJ.4L1: DFXJ;
DFXJ.4R1: DFXJ;
DFXJ.4L5: DFXJ;
DFXJ.4R5: DFXJ;
! D1
!exec,install_ir15_b12(BPMWC.4, posBPMWC );
exec,install_ir15_cmn(MBXF.4, posD1);
exec,install_ir15_cmn(DFXJ.4, posDFXJ);
!===============================================
!BPM triplet D1
!===============================================
! to be changed
! Q1 | .5 } .526 BPM .172 {.5 | MCBXFBa
! MCBXFBa | Q2a | .5 } .054 BPM .812 {.5 | Q2b
! MCBXFBb | .0} .392 BPM .805 {.5 | Q3
! Q3 | .5 } .047 BPM ...
! BMPSQW is between TAS and Q1
l.BPMSQ = 0.2*0; !needs zero lengths BPMs
l.BPMSQW = 0.2*0;
BPMSQ : MONITOR, L := l.BPMSQ; ! bpm in the triplets
BPMSQT: MONITOR, L := l.BPMSQ; ! bpm in the triplets with W insert
BPMSQW: MONITOR, L := l.BPMSQW; ! bpm in the triplets warm
posBPM1 := posQ1a - l.MQXFA/2 - 1.067;!BPMSQ.1R5.B1
posBPM2 := posQ1b + l.MQXFA/2 + 1.047+0.100;!BPMSQ.A2R5.B1
posBPM3 := posQ2a + l.MQXFB/2 + 1.054+0.100;!BPMSQT.B2R5.B1
posBPM4 := posQ3a - l.MQXFA/2 - 1.047+0.100;!BPMSQ.A3R5.B1
posBPM5 := posQ3b + l.MQXFA/2 + 1.047+0.100;!BPMSQ.B3R5.B1
posBPM6 := posD1 - l.MBXF/2 - 1.050+0.100;!BPMSQ.4R5.B1
posBPM7 := posD1 + l.MBXF/2 + 1.050+3.658+0.928+0.150+0.142 ;!BPMSQW.B4R5.B1 87.89=3.74*23.5
value, posBPM1,posBPM2,posBPM3,posBPM4,posBPM5,posBPM6,posBPM7;
! xpos=array([21.853,33.073,43.858,54.643,65.743,87.89])
! c_[abs(a),abs(a-1)].min(axis=1)*3.74
! array([ 0.587, 0.587, 1.022, 1.457, 1.577, 1.87 ])
BPMSQ.1L1.B1 : BPMSQ; BPMSQ.1R1.B1 : BPMSQ;
BPMSQ.1L5.B1 : BPMSQ; BPMSQ.1R5.B1 : BPMSQ;
BPMSQ.1L1.B2 : BPMSQ; BPMSQ.1R1.B2 : BPMSQ;
BPMSQ.1L5.B2 : BPMSQ; BPMSQ.1R5.B2 : BPMSQ;
BPMSQ.A2L1.B1 : BPMSQ;BPMSQ.A2R1.B1 : BPMSQ;
BPMSQ.A2L5.B1 : BPMSQ;BPMSQ.A2R5.B1 : BPMSQ;
BPMSQ.A2L1.B2 : BPMSQ;BPMSQ.A2R1.B2 : BPMSQ;
BPMSQ.A2L5.B2 : BPMSQ;BPMSQ.A2R5.B2 : BPMSQ;
BPMSQT.B2L1.B1 : BPMSQT;BPMSQT.B2R1.B1 : BPMSQT;
BPMSQT.B2L5.B1 : BPMSQT;BPMSQT.B2R5.B1 : BPMSQT;
BPMSQT.B2L1.B2 : BPMSQT;BPMSQT.B2R1.B2 : BPMSQT;
BPMSQT.B2L5.B2 : BPMSQT;BPMSQT.B2R5.B2 : BPMSQT;
BPMSQ.A3L1.B1 : BPMSQ;BPMSQ.A3R1.B1 : BPMSQ;
BPMSQ.A3L5.B1 : BPMSQ;BPMSQ.A3R5.B1 : BPMSQ;
BPMSQ.A3L1.B2 : BPMSQ;BPMSQ.A3R1.B2 : BPMSQ;
BPMSQ.A3L5.B2 : BPMSQ;BPMSQ.A3R5.B2 : BPMSQ;
BPMSQ.B3L1.B1 : BPMSQ;BPMSQ.B3R1.B1 : BPMSQ;
BPMSQ.B3L5.B1 : BPMSQ;BPMSQ.B3R5.B1 : BPMSQ;
BPMSQ.B3L1.B2 : BPMSQ;BPMSQ.B3R1.B2 : BPMSQ;
BPMSQ.B3L5.B2 : BPMSQ;BPMSQ.B3R5.B2 : BPMSQ;
BPMSQ.4L1.B1 : BPMSQ; BPMSQ.4R1.B1 : BPMSQ;
BPMSQ.4L5.B1 : BPMSQ; BPMSQ.4R5.B1 : BPMSQ;
BPMSQ.4L1.B2 : BPMSQ; BPMSQ.4R1.B2 : BPMSQ;
BPMSQ.4L5.B2 : BPMSQ; BPMSQ.4R5.B2 : BPMSQ;
BPMSQW.4L1.B1 : BPMSQW;BPMSQW.4R1.B1 : BPMSQW;
BPMSQW.4L5.B1 : BPMSQW;BPMSQW.4R5.B1 : BPMSQW;
BPMSQW.4L1.B2 : BPMSQW;BPMSQW.4R1.B2 : BPMSQW;
BPMSQW.4L5.B2 : BPMSQW;BPMSQW.4R5.B2 : BPMSQW;
! BPMS
exec,install_ir15_b12(BPMSQ.1 , posBPM1 );
exec,install_ir15_b12(BPMSQ.A2, posBPM2 );
exec,install_ir15_b12(BPMSQT.B2, posBPM3 );
exec,install_ir15_b12(BPMSQ.A3, posBPM4 );
exec,install_ir15_b12(BPMSQ.B3, posBPM5 );
exec,install_ir15_b12(BPMSQ.4 , posBPM6 );
exec,install_ir15_b12(BPMSQW.4 , posBPM7 );
!===============================================
! D2 area
!===============================================
! TAN TCTV TCTH TCL BPMWQ 1.835 (left)
! TAN TCL BPMWQ 1.835 (right)
! {.4 D2 .4 MCBRDH .4 MCBRDV .4}
! B1-> 0.5 { 1.3 1.3 CRAB 2.6 CRAB 2.6 CRAB 1.3 } 2.69 | MCBYY
! B2<- 0.5 { 1.3 CRAB 2.6 CRAB 2.6 CRAB 1.3 1.3 } 2.69 | MCBYY
! D2
!l.MBRD=10;
!if (l.MBRD==0) {l.MBRD=7.8;};
!if (l.MCBRD==0) {l.MCBRD=1.5;};
l.BPMWQ=0.285*0;
MBRD : RBEND , L := l.MBRD ; ! D2
MCBRDH: HKICKER, L := l.MCBRD; ! long for crabs in D2 cryostats
MCBRDV: VKICKER, L := l.MCBRD; ! long for crabs in D2 cryostats
BPMWQ : MONITOR, L := l.BPMWQ; ! bpm in D2
posD2 := 157.9+deltaposD2; ! minimize distance D1-D2, maximum field 35 Tm
!posD2 = 157.9-8-7; ! from V6.503
! 8 to fit two cavitities with 1.5 meter at 163
!11 to fit three cavitities with 1.5 meter
posBPMWQ := posD2-l.MBRD/2-0.983-0.702-0.285/2;!BPMWQ.4R5.B1
posMCBRDA := posD2 + l.MBRD/2 + l.MCBRD/2 + 0.365;
posMCBRDB := posMCBRDA + l.MCBRD + 0.365;
MBRD.4L1.B1: MBRD, angle:=-ad2.l1, K0:=-kd2.l1, polarity=-1;
MBRD.4R1.B1: MBRD, angle:= ad2.r1, K0:= kd2.r1, polarity=+1;
MBRD.4L5.B1: MBRD, angle:=-ad2.l5, K0:=-kd2.l5, polarity=-1;
MBRD.4R5.B1: MBRD, angle:= ad2.r5, K0:= kd2.r5, polarity=+1;
MBRD.4L1.B2: MBRD, angle:=-ad2.l1, K0:=-kd2.l1, polarity=+1*bv_aux;
MBRD.4R1.B2: MBRD, angle:= ad2.r1, K0:= kd2.r1, polarity=-1*bv_aux;
MBRD.4L5.B2: MBRD, angle:=-ad2.l5, K0:=-kd2.l5, polarity=+1*bv_aux;
MBRD.4R5.B2: MBRD, angle:= ad2.r5, K0:= kd2.r5, polarity=-1*bv_aux;
MCBRDH.4L1.B1: MCBRDH, kick:= acbrdh4.l1b1;
MCBRDH.4R1.B1: MCBRDH, kick:= acbrdh4.r1b1;
MCBRDH.4L5.B1: MCBRDH, kick:= acbrdh4.l5b1;
MCBRDH.4R5.B1: MCBRDH, kick:= acbrdh4.r5b1;
MCBRDH.4L1.B2: MCBRDH, kick:=-acbrdh4.l1b2;
MCBRDH.4R1.B2: MCBRDH, kick:=-acbrdh4.r1b2;
MCBRDH.4L5.B2: MCBRDH, kick:=-acbrdh4.l5b2;
MCBRDH.4R5.B2: MCBRDH, kick:=-acbrdh4.r5b2;
MCBRDV.4L1.B1: MCBRDV, kick:= acbrdv4.l1b1*bv_aux;
MCBRDV.4R1.B1: MCBRDV, kick:= acbrdv4.r1b1*bv_aux;
MCBRDV.4L5.B1: MCBRDV, kick:= acbrdv4.l5b1*bv_aux;
MCBRDV.4R5.B1: MCBRDV, kick:= acbrdv4.r5b1*bv_aux;
MCBRDV.4L1.B2: MCBRDV, kick:=-acbrdv4.l1b2*bv_aux;
MCBRDV.4R1.B2: MCBRDV, kick:=-acbrdv4.r1b2*bv_aux;
MCBRDV.4L5.B2: MCBRDV, kick:=-acbrdv4.l5b2*bv_aux;
MCBRDV.4R5.B2: MCBRDV, kick:=-acbrdv4.r5b2*bv_aux;
BPMWQ.4L1.B1: BPMWQ;
BPMWQ.4R1.B1: BPMWQ;
BPMWQ.4L5.B1: BPMWQ;
BPMWQ.4R5.B1: BPMWQ;
BPMWQ.4L1.B2: BPMWQ;
BPMWQ.4R1.B2: BPMWQ;
BPMWQ.4L5.B2: BPMWQ;
BPMWQ.4R5.B2: BPMWQ;
! separation recombination powering, 0.194 m separation between apertures
ad1.lr1:=atan(0.194/2./(posD2-posD1))*(1-R0);
kd1.lr1:=ad1.lr1/l.MBXF;
ad1.lr5:=atan(0.194/2./(posD2-posD1))*(1-R0);
kd1.lr5:=ad1.lr5/l.MBXF;
ad2.l1 :=atan(0.194/2./(posD2-posD1))*(1-R0);
ad2.r1 :=atan(0.194/2./(posD2-posD1))*(1-R0);
kd2.l1 :=ad2.l1/l.MBRD;
kd2.r1 :=ad2.r1/l.MBRD;
ad2.l5 :=atan(0.194/2./(posD2-posD1))*(1-R0);
ad2.r5 :=atan(0.194/2./(posD2-posD1))*(1-R0);
kd2.l5 :=ad2.l5/l.MBRD;
kd2.r5 :=ad2.r5/l.MBRD;
value, posD1,posD2,posD2-posD1,posMCBRDA,posMCBRDB;
value, ad1.lr1,l.MBXF,ad1.lr1/l.MBXF*brho,ad1.lr1*brho;
value, ad2.l1,l.MBRD,ad2.l1/l.MBRD*brho,ad2.l1*brho;
! D2
exec,install_ir15_b12(MBRD.4 , posD2 );
exec,install_ir15_b12(BPMWQ.4, posBPMWQ);
!IP - D2 posMCBRDA posMCBRDB
! orientation:
! b1: h v - IP - v h
! b2: v h - IP - h v
!exec,install_ir15_b1_b2(MCBRDV.4,posMCBRDA,posMCBRDB);
!exec,install_ir15_b1_b2(MCBRDH.4,posMCBRDB,posMCBRDA);
! orientation:
! b1: h v - IP - h v
! b2: v h - IP - v h
exec,install_ir15_b1_b2_alt(MCBRDV.4,posMCBRDA,posMCBRDB);
exec,install_ir15_b1_b2_alt(MCBRDH.4,posMCBRDB,posMCBRDA);
!===============================================
! Q4
!===============================================
!l.MQYY =3.4+0.1;
!l.MQYY =3.5 3.675
!if (l.MQYY==0) { l.MQYY=3.826; };
!if (l.MCBYY==0 ) {l.MCBYY=1.50;};
posQ4 :=169.553+deltaPosQ4; !new layout (excel file) 182.644 m
posBPMYA.4 :=posQ4 + l.MQY/2 + 0.804 ;!BPMYA.4R5.B1
posMCBY.A4 :=posQ4 - l.MQY/2 - l.MCBYH/2 - 0.198;
posMCBY.B4 :=posMCBY.A4 - l.MCBYH - 0.337;
posMCBY.C4 :=posMCBY.B4 - l.MCBYH - 0.337;
posMCBY.D4 :=posMCBY.C4 - l.MCBYH - 0.337;
value,posQ4,posMCBY.A4,posMCBY.B4,posMCBY.C4,posMCBY.D4;
MCBYV.A4L1.B1:MCBYV, KICK:= acbyv4.l1b1, polarity=+1;
MCBYH.A4L1.B1:MCBYH, KICK:= acbyh4.l1b1, polarity=+1;
MCBYV.A4R1.B1:MCBYV, KICK:= acbyv4.r1b1, polarity=+1;
MCBYH.A4R1.B1:MCBYH, KICK:= acbyh4.r1b1, polarity=+1;
MCBYV.A4L5.B1:MCBYV, KICK:= acbyv4.l5b1, polarity=+1;
MCBYH.A4L5.B1:MCBYH, KICK:= acbyh4.l5b1, polarity=+1;
MCBYV.A4R5.B1:MCBYV, KICK:= acbyv4.r5b1, polarity=+1;
MCBYH.A4R5.B1:MCBYH, KICK:= acbyh4.r5b1, polarity=+1;
MCBYV.B4L1.B1:MCBYV, KICK:= acbyvs4.l1b1, polarity=+1;
MCBYH.B4L1.B1:MCBYH, KICK:= acbyhs4.l1b1, polarity=+1;
MCBYV.B4R1.B1:MCBYV, KICK:= acbyvs4.r1b1, polarity=+1;
MCBYH.B4R1.B1:MCBYH, KICK:= acbyhs4.r1b1, polarity=+1;
MCBYV.B4L5.B1:MCBYV, KICK:= acbyvs4.l5b1, polarity=+1;
MCBYH.B4L5.B1:MCBYH, KICK:= acbyhs4.l5b1, polarity=+1;
MCBYV.B4R5.B1:MCBYV, KICK:= acbyvs4.r5b1, polarity=+1;
MCBYH.B4R5.B1:MCBYH, KICK:= acbyhs4.r5b1, polarity=+1;
MCBYV.A4L1.B2:MCBYV, KICK:= -acbyv4.l1b2*bv_aux, polarity=+1;
MCBYH.A4L1.B2:MCBYH, KICK:= -acbyh4.l1b2, polarity=+1;
MCBYV.A4R1.B2:MCBYV, KICK:= -acbyv4.r1b2*bv_aux, polarity=+1;
MCBYH.A4R1.B2:MCBYH, KICK:= -acbyh4.r1b2, polarity=+1;
MCBYV.A4L5.B2:MCBYV, KICK:= -acbyv4.l5b2*bv_aux, polarity=+1;
MCBYH.A4L5.B2:MCBYH, KICK:= -acbyh4.l5b2, polarity=+1;
MCBYV.A4R5.B2:MCBYV, KICK:= -acbyv4.r5b2*bv_aux, polarity=+1;
MCBYH.A4R5.B2:MCBYH, KICK:= -acbyh4.r5b2, polarity=+1;
MCBYV.B4L1.B2:MCBYV, KICK:= -acbyvs4.l1b2*bv_aux, polarity=+1;
MCBYH.B4L1.B2:MCBYH, KICK:= -acbyhs4.l1b2, polarity=+1;
MCBYV.B4R1.B2:MCBYV, KICK:= -acbyvs4.r1b2*bv_aux, polarity=+1;
MCBYH.B4R1.B2:MCBYH, KICK:= -acbyhs4.r1b2, polarity=+1;
MCBYV.B4L5.B2:MCBYV, KICK:= -acbyvs4.l5b2*bv_aux, polarity=+1;
MCBYH.B4L5.B2:MCBYH, KICK:= -acbyhs4.l5b2, polarity=+1;
MCBYV.B4R5.B2:MCBYV, KICK:= -acbyvs4.r5b2*bv_aux, polarity=+1;
MCBYH.B4R5.B2:MCBYH, KICK:= -acbyhs4.r5b2, polarity=+1;
exec,newel_ir15_b12(BPMYA.4,BPMYA);
exec,install_ir15_b12(BPMYA.4, posBPMYA.4);
exec,install_ir15_b12(MQY.4 , posQ4 );
exec,install_ir15_b1_b2_alt(MCBYH.A4,posMCBY.C4,posMCBY.D4);
exec,install_ir15_b1_b2_alt(MCBYV.A4,posMCBY.D4,posMCBY.C4);
exec,install_ir15_b1_b2_alt(MCBYH.B4,posMCBY.A4,posMCBY.B4);
exec,install_ir15_b1_b2_alt(MCBYV.B4,posMCBY.B4,posMCBY.A4);
!===============================================
! Q5
!===============================================
!if (l.MQYL==0){l.MQYL=3.40;};
!MQYL: QUADRUPOLE, L := l.MQYL ; ! long MQY type
l.BPMQB= 0.0;! l.BPMQB = 0
BPMQB: MONITOR, L := l.BPMQB ; ! large ap. for Q5 maybe from old q4 ones
MQY.5R1.B1:MQY,K1 := kq5.r1b1, polarity=+1;
MQY.5L5.B1:MQY,K1 := kq5.l5b1, polarity=-1;
MQY.5R5.B1:MQY,K1 := kq5.r5b1, polarity=+1;
MQY.5L1.B1:MQY,K1 := kq5.l1b1, polarity=-1;
MQY.5R1.B2:MQY,K1 := -kq5.r1b2*bv_aux, polarity=-1;
MQY.5L5.B2:MQY,K1 := -kq5.l5b2*bv_aux, polarity=+1;
MQY.5R5.B2:MQY,K1 := -kq5.r5b2*bv_aux, polarity=-1;
MQY.5L1.B2:MQY,K1 := -kq5.l1b2*bv_aux, polarity=+1;
!MCBYH.5R1.B1: MCBYH, KICK := acbch5.r1b1, polarity=+1;
!MCBYV.5L5.B1: MCBYV, KICK := acbcv5.l5b1*bv_aux, polarity=+1;
!MCBYH.5R5.B1: MCBYH, KICK := acbch5.r5b1, polarity=+1;
!MCBYV.5L1.B1: MCBYV, KICK := acbcv5.l1b1*bv_aux, polarity=+1;
!MCBYV.5R1.B2: MCBYV, KICK := -acbcv5.r1b2*bv_aux, polarity=+1;
!MCBYH.5L5.B2: MCBYH, KICK := -acbch5.l5b2, polarity=+1;
!MCBYV.5R5.B2: MCBYV, KICK := -acbcv5.r5b2*bv_aux, polarity=+1;
!MCBYH.5L1.B2: MCBYH, KICK := -acbch5.l1b2, polarity=+1;
! MQY B - A for all MQY the B corrector is closest to the MQY
MCBYV.A5R1.B2:MCBYV, KICK:= acbyvs5.r1b2*bv_aux, polarity=+1;
MCBYH.5R1.B2 :MCBYH, KICK:= acbyhs5.r1b2, polarity=+1;
MCBYV.B5R1.B2:MCBYV, KICK:= acbyv5.r1b2*bv_aux, polarity=+1;
MCBYH.B5L5.B2:MCBYH, KICK:= acbyh5.l5b2, polarity=+1;
MCBYV.5L5.B2 :MCBYV, KICK:= acbyvs5.l5b2*bv_aux, polarity=+1;
MCBYH.A5L5.B2:MCBYH, KICK:= acbyhs5.l5b2, polarity=+1;
MCBYV.A5R5.B2:MCBYV, KICK:= acbyvs5.r5b2*bv_aux, polarity=+1;
MCBYH.5R5.B2 :MCBYH, KICK:= acbyhs5.r5b2, polarity=+1;
MCBYV.B5R5.B2:MCBYV, KICK:= acbyv5.r5b2*bv_aux, polarity=+1;
MCBYH.B5L1.B2:MCBYH, KICK:= acbyh5.l1b2, polarity=+1;
MCBYV.5L1.B2 :MCBYV, KICK:= acbyvs5.l1b2*bv_aux, polarity=+1;
MCBYH.A5L1.B2:MCBYH, KICK:= acbyhs5.l1b2, polarity=+1;
MCBYH.A5R1.B1:MCBYH, KICK:= -acbyhs5.r1b1, polarity=+1;
MCBYV.5R1.B1 :MCBYV, KICK:= -acbyvs5.r1b1*bv_aux, polarity=+1;
MCBYH.B5R1.B1:MCBYH, KICK:= -acbyh5.r1b1, polarity=+1;
MCBYV.B5L5.B1:MCBYV, KICK:= -acbyv5.l5b1*bv_aux, polarity=+1;
MCBYH.5L5.B1 :MCBYH, KICK:= -acbyhs5.l5b1, polarity=+1;
MCBYV.A5L5.B1:MCBYV, KICK:= -acbyvs5.l5b1*bv_aux, polarity=+1;
MCBYH.A5R5.B1:MCBYH, KICK:= -acbyhs5.r5b1, polarity=+1;
MCBYV.5R5.B1 :MCBYV, KICK:= -acbyvs5.r5b1*bv_aux, polarity=+1;
MCBYH.B5R5.B1:MCBYH, KICK:= -acbyh5.r5b1, polarity=+1;
MCBYV.B5L1.B1:MCBYV, KICK:= -acbyv5.l1b1*bv_aux, polarity=+1;
MCBYH.5L1.B1 :MCBYH, KICK:= -acbyhs5.l1b1, polarity=+1;
MCBYV.A5L1.B1:MCBYV, KICK:= -acbyvs5.l1b1*bv_aux, polarity=+1;
posQ5 := 196.490 + deltaPosQ5; !new layout (excel file): 207.49
!position set for IR5 right
dposBPMY.5 := l.MQY/2 + 0.974; !BPMYA.4L5.B1:BPMYA BPMYA.4L5.B2:BPMYA
dposMCBY.B5 := (l.MQY + l.MCBYV)/2 + 0.372; !same as nominal note that in IR2-8-6 distance can
dposMCBY.5 := dposMCBY.B5 + (l.MCBYH + l.MCBYV)/2 + 0.396; !be better