CLOG UI for command-line scripts

[khinsen]

I am playing with the idea of making small personal tools as Common Lisp scripts (called from a terminal) that use CLOG for displaying a GUI. Such a script would

1. Initialize CLOG
2. Open a browser window for its GUI.
3. When the browser window/tab is closed, terminate.

What I don't know how to do is the last step. There doesn't seem to be an event associated with closing of a browser window/tab. There something called when a WebSocket connection is closed, but it's labelled "private" (and apparently not extensible).

What I could do (but don't like) is checking clog-connection::*connections* once per second and terminate if its size drops to zero.

Is there a better way?

[rabbibotton]

You use (run body) it is what it is designed for :)

It blocks until the connection to the browser done.

[khinsen]

Nice!

This requires a body, so I have to put it into my on-new-window handler, right? That works (see example below), but I have to add (sleep 5) to the end of script to prevent it from exiting before on-new-window is actually called.

#!/usr/bin/env sbcl --script

(load (merge-pathnames "quicklisp/setup.lisp"
                       (user-homedir-pathname)))
(ql:quickload :clog)

(defun on-new-window (body)
  (setf (clog:title (clog:html-document body)) "Tutorial 01")
  (let ((hello-element
          (clog:create-child body "<h1>Hello World! (click me!)</h1>")))
    (clog:set-on-click hello-element
                       (lambda (obj)
                         (declare (ignore obj))
                         (setf (clog:color hello-element) :green))))
  (clog:run body))

(clog:initialize #'on-new-window)
(clog:open-browser)
(sleep 5)

[rabbibotton]

Yes unless have some other code to run, you may want to consider a longer wait depending on your needs as that would be the default of how long your app would wait terminate if a browser did not open or the user click to start and place (uiop:quit) after the (clog:run body). The builder similar when run as an exe

[khinsen]

Quitting in the handler is a nice trick! I added clog:shutdown (gets rid of an error message from hunchentoot), and replaced sleep by an infinite wait for a semaphore:

#!/usr/bin/env sbcl --script

(load (merge-pathnames "quicklisp/setup.lisp"
                       (user-homedir-pathname)))
(ql:quickload :clog)

(defun on-new-window (body)
  (setf (clog:title (clog:html-document body)) "Tutorial 01")
  (let ((hello-element
          (clog:create-child body "<h1>Hello World! (click me!)</h1>")))
    (clog:set-on-click hello-element
                       (lambda (obj)
                         (declare (ignore obj))
                         (setf (clog:color hello-element) :green))))
  (clog:run body)
  (clog:shutdown)
  (uiop:quit))

(clog:initialize #'on-new-window)
(clog:open-browser)

(let ((sem (bordeaux-threads:make-semaphore)))
  (bordeaux-threads:wait-on-semaphore sem)))

[rabbibotton]

That of course is the best way :)

[khinsen]

This being Lisp, let's hide all this machinery in a reusable function:

#!/usr/bin/env sbcl --script

(load (merge-pathnames "quicklisp/setup.lisp"
                       (user-homedir-pathname)))
(ql:quickload :clog)

(defun create-window-and-wait-for-close (on-new-window-handler)
  "Open a browser window whose contents is defined by
   ON-NEW-WINDOW-HANDLER. Wait until the user closes that window.

   NOTE: This function initializes CLOG at the beginning and shuts it
   down in the end."
  (let ((sem (bordeaux-threads:make-semaphore)))
    (flet ((on-new-window-wrapper (body)
             (funcall on-new-window-handler body)
             (clog:run body)
             (bordeaux-threads:signal-semaphore sem)))
      (clog:initialize #'on-new-window-wrapper))
    (clog:open-browser)
    (bordeaux-threads:wait-on-semaphore sem)
    (clog:shutdown)))

(defun on-new-window (body)
  (setf (clog:title (clog:html-document body)) "Tutorial 01")
  (let ((hello-element
          (clog:create-child body "<h1>Hello World! (click me!)</h1>")))
    (clog:set-on-click hello-element
                       (lambda (obj)
                         (declare (ignore obj))
                         (setf (clog:color hello-element) :green)))))

(create-window-and-wait-for-close #'on-new-window)