settings.gradle

pluginManagement {
    plugins {
        // Gradle is awkward about declaring versions for plugins
        // Specifying it here, rather than build.gradle, makes it possible
        // to include the extension as a subproject of QuPath itself
        // (which is useful during development)
        id 'org.bytedeco.gradle-javacpp-platform' version '1.5.8'
    }
}

// Name your QuPath extension here!
rootProject.name = 'BasicStitching'

// Define the QuPath version compatible with the extension
// Note that the QuPath API isn't stable; something designed for
// 0.X.a should work with 0.X.b, but not necessarily with 0.Y.a.
gradle.ext.qupathVersion = "0.4.4"

dependencyResolutionManagement {

    // Access QuPath's version catalog for dependency versions
    versionCatalogs {
        libs {
            from("io.github.qupath:qupath-catalog:${gradle.ext.qupathVersion}")
        }
    }

    repositories {

        mavenCentral()

        // Add scijava - which is where QuPath's jars are hosted
        maven {
            url "https://maven.scijava.org/content/repositories/releases"
        }

        maven {
            url "https://maven.scijava.org/content/repositories/snapshots"
        }
        maven {
            url "https://maven.scijava.org/content/groups/public"
        }

    }
}