build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }

    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

repositories {
	maven {
		name = "ic2"
		url = "http://maven.ic2.player.to/"
	}
	maven {
		name = "calclavia"
		url = "http://localhost/maven/"
	}

    maven{
        name "Waila Mobius Repo"
        url "http://localhost/maven/"
    }

    maven{
        name "CB Maven FS"
        url "http://chickenbones.net/maven/"
    }

    ivy {
        url "http://www.mod-buildcraft.com/releases/BuildCraft/"
        layout 'pattern', {
            ivy '[revision]/[module]-[revision]-dev-ivy.xml'
            artifact '[revision]/[module]-[revision]-dev(.[ext])'
        }
    }
}

apply plugin: 'forge'
apply plugin: 'maven'
apply plugin: 'curseforge'

// define the properties file
ext.configFile = file "build.properties"

configFile.withReader {
    // read config.  it shall from now on be referenced as simply config or as project.config
    def prop = new Properties()
    prop.load(it)
    ext.config = new ConfigSlurper().parse prop
}

version = config.modVersion
group= "powercrystals.powerconverters" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "PowerConverters"

dependencies {
	compile "net.industrial-craft:industrialcraft-2:${config.ic2_version}:api"
	compile "com.mod-buildcraft:buildcraft:${config.buildcraft_version}:dev"
	compile "dev.calclavia.resonantengine:resonant-engine:${config.resonantengine_version}:dev"
    compile "mcp.mobius.waila:Waila:${config.waila_version}:dev"
}

minecraft {
	version = config.minecraft_version + "-" + config.forge_version
}

String buildNumber = "unknown"
version = "${config.minecraft_version}_${config.mod_version}"
if(System.getenv("BUILD_NUMBER") != null) {
    buildNumber = System.getenv("BUILD_NUMBER")
    version = "${config.minecraft_version}_${config.mod_version}-jenkins.${buildNumber}"
}

processResources
{
    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version, 'buildnumber': "${System.getenv().BUILDNUMBER}"
    }
        
    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'

}

build.dependsOn deobfJar

artifacts {
    archives deobfJar
}

configurations {
    deployerJars
}

uploadArchives {
    dependsOn 'reobf'
    repositories {
        if(project.hasProperty("pushMaven")) {
            logger.info("Pushing to maven repo")
            mavenDeployer {
                configuration = configurations.deployerJars
                repository(url: "file://localhost/home/public_html/maven.jamesmckay.id.au/htdocs/")
                pom {
                    groupId = project.group
                    version = project.version
                    artifactId = project.archivesBaseName
                    packaging = 'jar'
                    description 'PowerConverters Mod'
                }
            }
        }
    }
}

ext.curseForgeReleaseType = null

task ('curseGeneral') << {
    curse {
        projectId = '229499'
        if (project.hasProperty('curseForgeApiKey')) apiKey = project.curseForgeApiKey
        else apiKey = 0
        releaseType = curseForgeReleaseType
        changelog = new File('Changelog.md').getText('utf-8').split('\n-{3,8}|\n\n')[2]
        displayName = String.format('PowerConverters %s [build %s]', config.mod_version, buildNumber)
        additionalArtifact deobfJar

        for (String newVersion : config.compatible_versions.split(",")) {
            addGameVersion newVersion
        }
    }.execute()
}

task setCurseAlpha << {
    print('Set alpha\n')
    curseForgeReleaseType = 'alpha'
}
task setCurseBeta << {
    print('Set beta\n')
    curseForgeReleaseType = 'beta'
}

task setCurseRelease << {
    print('Set release\n')
    curseForgeReleaseType = 'release'
}

task curseAlpha << {
    setCurseAlpha.execute()
    curseGeneral.execute()
}

task curseBeta << {
    setCurseBeta.execute()
    curseGeneral.execute()
}

task curseRelease << {
    setCurseRelease.execute()
    curseGeneral.execute()
}