Move to kotlin multiplatform plugin.

.gitignore

@@ -24,7 +24,7 @@
 bin/
 gen/
 out/
-!/ios/library/keychainwrapper/bin
+!/kissme/library/keychainwrapper/bin
 
 # Gradle files
 .gradle/
@@ -96,7 +96,7 @@ fabric.properties
 .LSOverride
 
 # ios cinterop .def file
-/ios/src/main/c_interop/keychainwrapper.def
+/kissme/src/nativeInterop/cinterop/keychainwrapper.def
 
 # Build-time secrets
 secret.properties

build.gradle

@@ -1,7 +1,7 @@
 apply from: 'versions.gradle'
 
 buildscript {
-    ext.kotlin_version = '1.3.41'
+    ext.kotlin_version = '1.3.60'
 
     repositories {
         maven { url 'https://dl.bintray.com/jetbrains/kotlin-native-dependencies' }
@@ -10,8 +10,7 @@ buildscript {
     }
     dependencies {
         classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
-        classpath "org.jetbrains.kotlin:kotlin-native-gradle-plugin:$kotlin_version"
-        classpath "com.android.tools.build:gradle:3.4.0"
+        classpath "com.android.tools.build:gradle:3.5.3"
         classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4'
     }
 }

gradle/wrapper/gradle-wrapper.properties

@@ -2,4 +2,4 @@ distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-5.1.1-all.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-5.4.1-all.zip

kissme/build.gradle

@@ -0,0 +1,141 @@
+plugins {
+    id("org.jetbrains.kotlin.multiplatform")
+}
+apply plugin: 'com.android.library'
+
+kotlin {
+    android {
+        publishLibraryVariants("release", "debug")
+    }
+
+    iosX64("iosX64") {
+        compilations.main.cinterops {
+            keychainwrapper {
+                packageName "com.netguru.keychainWrapper"
+                includeDirs {
+                    allHeaders "./library/keychainwrapper/bin"
+                }
+                compilerOpts "-F${projectDir}"
+            }
+        }
+    }
+
+    iosArm64("iosArm64") {
+        compilations.main.cinterops {
+            keychainwrapper {
+                packageName "com.netguru.keychainWrapper"
+                includeDirs {
+                    allHeaders "./library/keychainwrapper/bin"
+                }
+                compilerOpts "-F${projectDir}"
+            }
+        }
+    }
+
+    sourceSets {
+        commonMain {
+            dependencies {
+                implementation "org.jetbrains.kotlin:kotlin-stdlib-common"
+            }
+        }
+        commonTest {
+            dependencies {
+                implementation "org.jetbrains.kotlin:kotlin-test-annotations-common"
+                implementation "org.jetbrains.kotlin:kotlin-test-common"
+            }
+        }
+
+        androidMain {
+            dependencies {
+                implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
+                implementation "com.github.yandextaxitech:binaryprefs:1.0.1"
+            }
+        }
+        androidTest {
+            dependencies {
+                implementation "org.jetbrains.kotlin:kotlin-test-junit:$kotlin_version"
+                implementation "org.jetbrains.kotlin:kotlin-test:$kotlin_version"
+                implementation "io.mockk:mockk:1.9.3"
+                implementation "androidx.test:core:1.2.0"
+                implementation "androidx.test.ext:junit:1.1.1"
+                implementation "org.robolectric:robolectric:4.2"
+            }
+        }
+
+        iosMain {}
+        iosArm64Main.dependsOn iosMain
+        iosX64Main.dependsOn iosMain
+
+        iosTest {}
+        iosArm64Test.dependsOn iosTest
+        iosX64Test.dependsOn iosTest
+    }
+}
+
+android {
+    compileSdkVersion 28
+    defaultConfig {
+        minSdkVersion 23
+        targetSdkVersion 28
+        versionCode 1
+        versionName '1.0'
+    }
+    buildTypes {
+        release {
+            minifyEnabled false
+        }
+    }
+
+    sourceSets {
+        main {
+            manifest.srcFile 'src/androidMain/AndroidManifest.xml'
+            java.srcDirs = ['src/androidMain/java', 'src/androidMain/kotlin']
+            res.srcDirs = ['src/androidMain/res']
+        }
+    }
+}
+
+task generateCinteropConfig(type: Exec) {
+    workingDir "${projectDir}"
+    commandLine 'sh', "${projectDir}/generate_cinterop_conf.sh"
+}
+
+gradle.taskGraph.beforeTask { Task task ->
+    if (task.project.name.toLowerCase().contains("ios")) {
+        "sh ${projectDir}/generate_cinterop_conf.sh ${projectDir}".execute().text
+    }
+}
+
+task sourcesJar(type: Jar) {
+    classifier = 'sources'
+    from android.sourceSets.main.java.srcDirs
+}
+
+artifacts {
+    archives sourcesJar
+}
+publishing {
+    publications {
+        android(MavenPublication) {
+            artifact("$buildDir/outputs/aar/kissme-release.aar")
+            artifact sourcesJar
+            artifactId 'android'
+            version project.libraryVersion
+
+            pom.withXml {
+                def dependenciesNode = asNode().appendNode('dependencies')
+                // Iterate over the implementation dependencies (we don't want the test ones), adding a <dependency> node for each
+                configurations.implementation.allDependencies.each {
+                    // Ensure dependencies such as fileTree are not included in the pom.
+                    if (it.name != 'unspecified') {
+                        println(it.name)
+                        def dependencyNode = dependenciesNode.appendNode('dependency')
+                        dependencyNode.appendNode('groupId', it.group)
+                        dependencyNode.appendNode('artifactId', it.name)
+                        dependencyNode.appendNode('version', it.version)
+                    }
+                }
+            }
+        }
+    }
+}

ios/generate_cinterop_conf.sh → kissme/generate_cinterop_conf.sh

@@ -1,6 +1,6 @@
 #! /bin/bash
 current_dir=$1
-target_file_dir="$1/src/main/c_interop/"
+target_file_dir="$1/src/nativeinterop/cinterop/"
 target_file_name="keychainwrapper.def"
 
 rm -f "$target_file_dir$target_file_name"

settings.gradle

@@ -1,2 +1,2 @@
 enableFeaturePreview('GRADLE_METADATA')
-include ':android', ':ios', ':common'
+include ':kissme'